Reworked lxsession man page generation.
[lxde/lxsession.git] / configure.ac
1 AC_PREREQ([2.57])
2 AC_INIT(lxsession,[0.3.8], [],lxsession)
3 AM_INIT_AUTOMAKE([dist-bzip2])
4 AC_PROG_INTLTOOL(, [no-xml])
5 AM_MAINTAINER_MODE
6
7 AM_CONFIG_HEADER(config.h)
8
9 AC_PROG_CC
10 AC_PROG_INSTALL
11 AM_PROG_CC_C_O
12
13 AC_CHECK_FUNC([mkstemp],
14    AC_DEFINE(HAS_MKSTEMP,1,[Define to 1 if you have the 'mkstemp' function.]))
15
16 AC_ARG_ENABLE(man,
17        [AC_HELP_STRING([--enable-man],
18                [regenerate roff man pages from Docbook @<:@default=no@:>@])],
19        [enable_man="${enableval}"],
20        [enable_man=no]
21 )
22
23 PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= 2.6.0])
24 AC_SUBST(GTK_CFLAGS)
25 AC_SUBST(GTK_LIBS)
26
27 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.6.0])
28 AC_SUBST(GLIB_CFLAGS)
29 AC_SUBST(GLIB_LIBS)
30
31 AC_ARG_ENABLE(
32     [hal],
33     AS_HELP_STRING([--enable-hal],
34                    [Build with Linux HAL support for shutdown/reboot/suspend (default: yes)]),
35     use_hal=$enableval, use_hal="yes")
36
37 if test x"$use_hal" = x"yes"; then
38 dnl Check HAL support
39     hal_modules="dbus-1"
40     PKG_CHECK_MODULES(HAL, [$hal_modules], [have_hal=yes], [have_hal=no])
41
42     if test x"$have_hal" = x"yes"; then
43         AC_DEFINE([HAVE_HAL], [1], [Define to 1 if you have HAL.])
44     else
45         AC_MSG_ERROR([To use HAL support, you must have developing packages of dbus-glib-1 (>=0.31), or you can use --disable-hal to disable HAL support.])
46     fi
47 fi
48 AM_CONDITIONAL(USE_HAL, test "$use_hal" = "yes")
49 AC_SUBST(HAL_CFLAGS)
50 AC_SUBST(HAL_LIBS)
51
52 GETTEXT_PACKAGE=lxsession
53 #AM_GNU_GETTEXT([external])
54 AM_GNU_GETTEXT_VERSION(0.14.1)
55 AC_SUBST(GETTEXT_PACKAGE)
56 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
57
58 ALL_LINGUAS="af ar cs da de es et eu fa fi fr gl hr hu id it ja ko lt ml ms nb nl nn pl ps pt pt_BR ru sk sl sv tr uk ur ur_PK vi zh_CN zh_TW"
59 AM_GLIB_GNU_GETTEXT
60
61 if test x"$enable_man" = x"yes"; then
62         AC_PATH_PROG([XSLTPROC], [xsltproc])
63         if test -z "$XSLTPROC"; then
64                 enable_man=no
65         fi
66
67         dnl check for DocBook DTD and stylesheets in the local catalog.
68         JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
69                 [DocBook XML DTD V4.1.2], [], enable_man=no)
70         JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
71                 [DocBook XSL Stylesheets >= 1.70.1], [], enable_man=no)
72 fi
73
74 AM_CONDITIONAL(ENABLE_REGENERATE_MAN, test "x$enable_man" != "xno")
75
76 AC_OUTPUT([
77   Makefile
78   lxsession/Makefile
79   lxsession-logout/Makefile
80   po/Makefile.in
81   man/Makefile
82 ])
83
84 echo
85 echo LXSession.................................... : Version $VERSION
86 echo
87 echo Prefix....................................... : $prefix
88 echo Linux HAL support............................ : $use_hal
89 echo
90 echo The binary will be installed in $prefix/bin
91 echo
92 echo http://lxde.org/
93 echo
94 echo Have fun!
95 echo