Somme improvement to configure.ac (silent rules, libtool)
[lxde/lxpanel.git] / configure.ac
1 AC_PREREQ(2.53)
2 AC_INIT(lxpanel, 0.5.6, http://lxde.org/)
3 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign])
4 AC_CONFIG_HEADER([config.h])
5
6 # Support silent build rules. Disable by either passing --disable-silent-rules
7 # to configure or passing V=1 to make
8 AM_SILENT_RULES([yes])
9
10 # Force to dynamic
11 AC_DISABLE_STATIC
12
13 # Checks for programs.
14 AC_PROG_CC
15 AC_PROG_INSTALL
16 AC_PROG_LN_S
17 AC_PROG_INTLTOOL(, [no-xml])
18 AM_PROG_CC_C_O
19
20 #Initialize libtool
21 LT_PREREQ([2.2])
22 LT_INIT
23
24 # Checks for libraries.
25 pkg_modules="gtk+-2.0 >= 2.12.0 \
26              gio-unix-2.0 \
27              gthread-2.0"
28 #             libstartup-notification-1.0"
29 PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
30 AC_SUBST(PACKAGE_CFLAGS)
31 AC_SUBST(PACKAGE_LIBS)
32
33 pkg_modules="x11"
34 PKG_CHECK_MODULES(X11, [$pkg_modules])
35 AC_SUBST(X11_LIBS)
36
37 pkg_modules="libmenu-cache"
38 PKG_CHECK_MODULES(MENU_CACHE, [$pkg_modules],
39                   enable_menu_cache=yes, enable_menu_cache=no)
40 if test x"$enable_menu_cache" = "xno"; then
41         AC_WARN([No libmenu-cache found.  All menu related routines are not built.])
42         AC_DEFINE(DISABLE_MENU, [1], [Disable menu related routines])
43 fi
44 AC_SUBST(MENU_CACHE_CFLAGS)
45 AC_SUBST(MENU_CACHE_LIBS)
46 AM_CONDITIONAL(ENABLE_MENU_CACHE, test x"$enable_menu_cache" = x"yes") 
47
48 PACKAGE_CFLAGS="$PACKAGE_CFLAGS $MENU_CACHE_CFLAGS"
49 PACKAGE_LIBS="$PACKAGE_LIBS $MENU_CACHE_LIBS"
50
51 AC_ARG_ENABLE(man,
52         [AC_HELP_STRING([--enable-man],
53                 [regenerate roff man pages from Docbook @<:@default=no@:>@])],
54         [enable_man="${enableval}"],
55         [enable_man=no]
56 )
57
58 AC_ARG_ENABLE([cast-checks],
59     AS_HELP_STRING([--enable-cast-checks],
60                [enable Glib casting checks (default: disable)]),
61                cast_checks=$enableval, cast_checks="no")
62 G_CAST_CHECKS=""
63 if test x"$cast_checks" = "xno"; then
64     G_CAST_CHECKS="-DG_DISABLE_CAST_CHECKS"
65 fi
66 AC_SUBST(G_CAST_CHECKS)
67
68 dnl linker tweaking
69 # The function of the link flag --as-needed is to prevent unnecesary linking.
70 # Example: A -> B -> C
71 # Normally, A would link to B and also depend on C, this is of cource
72 # unnecesary. In this situation, however we do need to link to C, so this
73 # must be done explicitly. This flag comes in handy when a library ABI
74 # is changed, minimizing the amount of recompilations needed.
75 AC_MSG_CHECKING([whether $LD accepts --as-needed])
76 case `$LD --as-needed -v 2>&1 </dev/null` in
77 *GNU* | *'with BFD'*)
78     LDFLAGS="$LDFLAGS -Wl,--as-needed"
79     AC_MSG_RESULT([yes])
80     ;;
81 *)
82     AC_MSG_RESULT([no])
83     ;;
84 esac
85
86 dnl linker optimizations
87 AC_MSG_CHECKING([whether $LD accepts -O1])
88 case `$LD -O1 -v 2>&1 </dev/null` in
89 *GNU* | *'with BFD'*)
90   LDFLAGS="$LDFLAGS -Wl,-O1"
91   AC_MSG_RESULT([yes])
92   ;;
93 *)
94   AC_MSG_RESULT([no])
95   ;;
96 esac
97 AC_MSG_CHECKING([whether $LD accepts -Bsymbolic-functions])
98 case `$LD -Bsymbolic-functions -v 2>&1 </dev/null` in
99 *GNU* | *'with BFD'*)
100   LDFLAGS="$LDFLAGS -Wl,-Bsymbolic-functions"
101   AC_MSG_RESULT([yes])
102   ;;
103 *)
104   AC_MSG_RESULT([no])
105   ;;
106 esac
107 AC_MSG_CHECKING([whether $LD accepts --sort-common])
108 case `$LD --sort-common -v 2>&1 </dev/null` in
109 *GNU* | *'with BFD'*)
110   LDFLAGS="$LDFLAGS -Wl,--sort-common"
111   AC_MSG_RESULT([yes])
112   ;;
113 *)
114   AC_MSG_RESULT([no])
115   ;;
116 esac
117
118 dnl FIXME: filter for undefined symbols in plugins
119 # when passing "-z defs" to linker, we would better to make sure
120 # there are no undefined references.  However, we intend not to
121 # fix at the moment since we don't have spin-off libraray containing
122 # the necessary functions.
123 if test ! -z "$LDFLAGS"; then
124     LDFLAGS=`echo "$LDFLAGS" | sed -e 's/-Wl,-z,defs//'`
125 fi
126
127 LXPANEL_MODULE="-avoid-version \
128 -rpath \$(libdir)/lxpanel/plugins \
129 -no-undefined "'-export-symbols-regex "^[[^_]].*"'
130 AC_SUBST(LXPANEL_MODULE)
131
132 AC_ARG_ENABLE([alsa],
133     AS_HELP_STRING([--disable-alsa],
134                     [compile ALSA providers (default: enable)]),
135             compile_alsa=$enableval, compile_alsa="yes")
136 if test x"$compile_alsa" = "xyes"; then
137     AC_CHECK_HEADERS([alsa/asoundlib.h],
138                      [AC_CHECK_LIB([asound],
139                                    [snd_seq_open],
140                                    compile_alsa=yes,compile_alsa=no)],
141                           compile_alsa=no)
142 fi
143 AM_CONDITIONAL(BUILD_ALSA_PLUGINS, test x$compile_alsa = xyes)
144 dnl FIXME: check OSS existence
145 AM_CONDITIONAL(BUILD_OSS_PLUGINS, test x$compile_alsa = xno)
146
147 AC_ARG_ENABLE([plugins-loading],
148     AS_HELP_STRING([--disable-plugins-loading],
149                [disable plugin loading (default: enable)]),
150                plugins_loading=$enableval, plugins_loading="yes")
151
152 AM_CONDITIONAL(BUILD_PLUGIN_LOADER, test x$plugins_loading = xyes)
153
154 if test x"$plugins_loading" = "xno"; then
155     AC_DEFINE(DISABLE_PLUGINS_LOADING, [1], [Disable plugin loading])
156 fi
157
158 dnl Here are plugin listing.
159 plugin_netstatus=
160 plugin_volume=
161 plugin_volumealsa=
162 plugin_cpu=
163 plugin_deskno=
164 plugin_batt=
165 plugin_xkb=
166 plugin_kbled=
167 plugin_thermal=
168 plugin_cpufreq=
169
170 AC_MSG_CHECKING([which plugins should be built dynamically])
171 AC_ARG_WITH(plugins,
172 [  --with-plugins=<list>  compile dynamic plugins in <list> ]
173 [                         plugins may be comma separated ]
174 [                         'all' builds all plugins (default), 'none' builds none ]
175 [                         Possible plugins are: ]
176 [                         netstatus, volume, volumealsa, cpu, deskno, batt, kbled, xkb, thermal, cpufreq], plugins="$withval",[plugins="all"])
177
178 if test x"$plugins" != xall -a x"$plugins" != xnone; then
179     if test x"$plugins_loading" = xno; then
180         AC_MSG_ERROR(
181         [--disable-plugins-loading and --with-plugins conflict each other.])
182     fi
183 fi
184
185 ALL_PLUGINS_LIST="netstatus volume volumealsa cpu deskno batt kbled xkb thermal cpufreq"
186 AC_SUBST(ALL_PLUGINS_LIST)
187
188 if test x"$plugins" = xall; then
189 dnl    for name in $ALL_PLUGINS
190 dnl    do
191 dnl        export plugin_$name="$name"
192 dnl    done
193
194     plugin_netstatus=netstatus
195     plugin_volume=volume
196     plugin_volumealsa=volumealsa
197     plugin_cpu=cpu
198     plugin_deskno=deskno
199     plugin_batt=batt
200     plugin_kbled=kbled
201     plugin_xkb=xkb
202     plugin_thermal=thermal
203     plugin_cpufreq=cpufreq
204
205     AC_MSG_RESULT(all)
206 else
207     if test "$plugins" != "none"; then
208         plugins=`echo $plugins | sed 's/,/ /g'`
209         for plugin in $plugins
210         do
211         case "$plugin" in
212             netstatus)
213                 plugin_netstatus=netstatus
214                 ;;
215             volume)
216                 plugin_volume=volume
217                 ;;
218             volumealsa)
219                 plugin_volumealsa=volumealsa
220                 ;;
221             cpu)
222                 plugin_cpu=cpu
223                 ;;
224             deskno)
225                 plugin_deskno=deskno
226                 ;;
227             batt)
228                 plugin_batt=batt
229                 ;;
230             kbled)
231                 plugin_kbled=kbled
232                 ;;
233             xkb)
234                 plugin_xkb=xkb
235                 ;;
236             thermal)
237                 plugin_thermal=thermal
238                 ;;
239             cpufreq)
240                 plugin_cpufreq=cpufreq
241                 ;;
242             *)
243                 echo "Unknown plugin $plugin."
244                 exit 1
245                 ;;
246         esac
247         done
248         AC_MSG_RESULT($plugins)
249     fi
250 fi
251
252 dnl FIXME: OSS/ALSA checking
253 if test x"$compile_alsa" = "xno"; then
254     if test ! -z $plugin_volumealsa; then
255         AC_MSG_RESULT([no ALSA headers/libraries found!])
256         plugin_volumealsa=
257     fi
258 else
259     dnl force OSS plugin to <null>
260     plugin_volume=
261 fi
262 PLUGINS_LIST="\
263     $plugin_netstatus \
264     $plugin_volume \
265     $plugin_volumealsa \
266     $plugin_cpu \
267     $plugin_deskno \
268     $plugin_batt \
269     $plugin_kbled \
270     $plugin_xkb \
271     $plugin_thermal \
272     $plugin_cpufreq"
273
274 AC_SUBST(PLUGINS_LIST)
275
276
277 # Checks for header files.
278 AC_PATH_X
279 AC_HEADER_STDC
280 AC_HEADER_SYS_WAIT
281 AC_CHECK_HEADERS([locale.h stdlib.h string.h sys/time.h unistd.h])
282
283 # Checks for typedefs, structures, and compiler characteristics.
284 AC_C_CONST
285 AC_C_INLINE
286 AC_STRUCT_TM
287
288 # Checks for library functions.
289 AC_FUNC_MALLOC
290 AC_FUNC_MEMCMP
291 AC_TYPE_SIGNAL
292 AC_FUNC_STAT
293 AC_FUNC_STRFTIME
294 AC_CHECK_FUNCS([bzero memset mkdir setlocale strchr])
295
296
297 GETTEXT_PACKAGE=lxpanel
298 #AM_GNU_GETTEXT([external])
299 AM_GNU_GETTEXT_VERSION(0.14.1)
300 AC_SUBST(GETTEXT_PACKAGE)
301 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
302
303 ALL_LINGUAS="af ar cs da de es et eu fa fi fr gl hu hr id it ja ko lt ml ms nb nl nn pl ps pt pt_BR ru sk sl sv tr uk ur ur_PK vi zh_CN zh_TW"
304 AM_GLIB_GNU_GETTEXT
305
306 if test x"$enable_man" = x"yes"; then
307         AC_PATH_PROG([XSLTPROC], [xsltproc])
308         if test -z "$XSLTPROC"; then
309                 enable_man=no
310         fi
311
312         dnl check for DocBook DTD and stylesheets in the local catalog.
313         JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
314                 [DocBook XML DTD V4.1.2], [], enable_man=no)
315         JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
316                 [DocBook XSL Stylesheets >= 1.70.1], [], enable_man=no)
317 fi
318
319 AM_CONDITIONAL(ENABLE_REGENERATE_MAN, test "x$enable_man" != "xno")
320
321 AC_CONFIG_FILES([
322     lxpanel.pc
323     Makefile
324     src/Makefile
325     src/plugins/Makefile
326     src/plugins/netstatus/Makefile
327     src/plugins/volume/Makefile
328     src/plugins/volumealsa/Makefile
329     src/plugins/cpu/Makefile
330     src/plugins/deskno/Makefile
331     src/plugins/batt/Makefile
332     src/plugins/kbled/Makefile
333     src/plugins/xkb/Makefile
334     src/plugins/thermal/Makefile
335     src/plugins/cpufreq/Makefile
336     po/Makefile.in
337     data/Makefile
338     data/default/panels/panel
339     man/Makefile
340 ])
341 AC_OUTPUT
342
343 echo
344 echo lxpanel ......................... : Version $VERSION
345 echo
346 echo Prefix........................... : $prefix
347 if test x$plugins_loading = xyes; then
348 echo Building dynamic plugins:
349     if test x"$plugin_netstatus" != x; then
350         AC_MSG_RESULT([    netstatus - Monitor networking status])
351     fi
352     if test x"$plugin_volume" != x; then
353         AC_MSG_RESULT([    volume - Display and adjust volume of sound card for OSS])
354     fi
355     if test x"$plugin_volumealsa" != x; then
356         AC_MSG_RESULT([    volumealsa - Display and adjust volume of sound card for ALSA])
357     fi
358     if test x"$plugin_cpu" != x; then
359         AC_MSG_RESULT([    cpu - Display CPU loading])
360     fi
361     if test x"$plugin_deskno" != x; then
362         AC_MSG_RESULT([    deskno - Display desktop number])
363     fi
364     if test x"$plugin_batt" != x; then
365         AC_MSG_RESULT([    batt - Monitor battery status])
366     fi
367     if test x"$plugin_kbled" != x; then
368         AC_MSG_RESULT([    kbled - Indicator for CapsLock, NumLock, and ScrLock])
369     fi
370     if test x"$plugin_xkb" != x; then
371         AC_MSG_RESULT([    xkb - Keyboard layout switcher])
372     fi
373     if test x"$plugin_thermal" != x; then
374         AC_MSG_RESULT([    thermal - Temperature monitor])
375     fi
376     if test x"$plugin_cpufreq" != x; then
377         AC_MSG_RESULT([    cpufreq - CpuFreq frontend])
378     fi
379 else
380 echo Dynamic loader for plugins....... : disabled.
381 fi
382
383 echo
384 echo 'LXPanel requires menu-cache and lxmenu-data packages since'
385 echo 'version 0.4.0. Please make sure they are correctly installed.'
386 echo 'Otherwise, you will not be able to use applications menu.'
387 echo
388