Merge branch 'use-libfm'
[lxde/lxpanel.git] / configure.ac
1 AC_PREREQ(2.53)
2 AC_INIT(lxpanel, 0.6.1, http://lxde.org/)
3 AM_INIT_AUTOMAKE([-Wall foreign no-dist-gzip dist-xz])
4 AC_CONFIG_HEADER([config.h])
5 AC_CONFIG_MACRO_DIR([m4])
6
7 # Support silent build rules. Disable by either passing --disable-silent-rules
8 # to configure or passing V=1 to make
9 AM_SILENT_RULES([yes])
10
11 # Force to dynamic
12 AC_DISABLE_STATIC
13
14 # Checks for programs.
15 AC_PROG_CC
16 AC_PROG_INSTALL
17 AC_PROG_LN_S
18 AC_PROG_INTLTOOL(, [no-xml])
19 AM_PROG_CC_C_O
20 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
21
22 #Initialize libtool
23 LT_PREREQ([2.2])
24 LT_INIT
25
26 # Checks for libraries.
27 AC_ARG_ENABLE(gtk3,
28 AC_HELP_STRING([--enable-gtk3],[enable to use gtk-3.0 instead of gtk-2.0]),
29 [case "${enableval}" in
30   yes)  enable_gtk3=yes ;;
31   no)   enable_gtk3=no ;;
32   *) AC_MSG_ERROR([bad value "${enableval}" for --enable-gtk3, use "yes" (default) or "no".]) ;;
33 esac],[])
34
35 if test "x$enable_gtk3" = "xyes" ; then
36   CFLAGS="$CFLAGS -DENABLE_GTK3"
37   pkg_modules="$pkg_modules gtk+-3.0 libfm-gtk3 >= 1.2.0"
38 else
39   pkg_modules="$pkg_modules gtk+-2.0 >= 2.16.0 libfm-gtk >= 1.2.0"
40 fi
41
42 pkg_modules="$pkg_modules \
43              gio-unix-2.0 \
44              gthread-2.0 \
45              gmodule-2.0 \
46              libmenu-cache"
47 PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
48 AC_SUBST(PACKAGE_CFLAGS)
49 AC_SUBST(PACKAGE_LIBS)
50
51 ###########################
52 # Indicator Info
53 ###########################
54 AC_ARG_ENABLE([indicator_support],
55     AS_HELP_STRING([--enable-indicator-support],
56                [enable plugin loading (default: disable)]),
57                indicator_support=$enableval, indicator_support="no")
58 AM_CONDITIONAL(ENABLE_INDICATOR_SUPPORT, test x"$indicator_support" = x"yes")
59
60 if test "$indicator_support" != "no"; then
61         INDICATOR_REQUIRED_VERSION=0.3.0
62         INDICATOR_PKG_NAME=indicator-0.4
63
64         PKG_CHECK_MODULES(APPLET, $INDICATOR_PKG_NAME >= $INDICATOR_REQUIRED_VERSION)
65         AC_SUBST(APPLET_CFLAGS)
66
67         if test "x$with_localinstall" = "xyes"; then
68                 INDICATORDIR="${libdir}/indicators/2/"
69                 INDICATORICONSDIR="${datadir}/indicator-applet/icons/"
70         else
71                 INDICATORDIR=`$PKG_CONFIG --variable=indicatordir $INDICATOR_PKG_NAME`
72                 INDICATORICONSDIR=`$PKG_CONFIG --variable=iconsdir $INDICATOR_PKG_NAME`
73 fi
74         AC_SUBST(INDICATORDIR)
75         AC_SUBST(INDICATORICONSDIR)
76 fi
77
78
79 pkg_modules="x11"
80 PKG_CHECK_MODULES(X11, [$pkg_modules])
81 AC_SUBST(X11_LIBS)
82
83 pkg_modules="libwnck-1.0"
84 PKG_CHECK_MODULES(WNCK, [$pkg_modules])
85 AC_SUBST(WNCK_CFLAGS)
86 AC_SUBST(WNCK_LIBS)
87
88 pkg_modules="libmenu-cache"
89 PKG_CHECK_MODULES(MENU_CACHE, [$pkg_modules],
90                   enable_menu_cache=yes, enable_menu_cache=no)
91 if test x"$enable_menu_cache" = "xno"; then
92         AC_WARN([No libmenu-cache found.  All menu related routines are not built.])
93         AC_DEFINE(DISABLE_MENU, [1], [Disable menu related routines])
94 fi
95 AC_SUBST(MENU_CACHE_CFLAGS)
96 AC_SUBST(MENU_CACHE_LIBS)
97 AM_CONDITIONAL(ENABLE_MENU_CACHE, test x"$enable_menu_cache" = x"yes")
98
99 AC_ARG_ENABLE(more_warnings,
100        [AC_HELP_STRING([--enable-more-warnings],
101                [Add more warnings @<:@default=no@:>@])],
102        [enable_more_warnings="${enableval}"],
103        [enable_more_warnings=no]
104 )
105
106 if test x"$enable_more_warnings" = x"yes"; then
107   ADDITIONAL_FLAGS="-Wall -Werror=all -Werror=format -Werror=implicit-function-declaration -Werror=implicit-int -Werror=missing-braces -Werror=parentheses -Werror=return-type -Werror=strict-aliasing -Werror=switch -Wuninitialized -Werror=unused-label -Werror=unused-value -Wextra -Wno-missing-field-initializers -Wno-unused-parameter -Werror=missing-declarations -Wredundant-decls -Wmissing-noreturn -Wpointer-arith -Wcast-align -Wwrite-strings -Werror=inline -Werror=format-nonliteral -Wformat-nonliteral -Werror=format-security -Wformat-security -Winit-self -Werror=missing-include-dirs -Werror=undef -Werror=aggregate-return -Wmissing-format-attribute -Werror=nested-externs -fno-strict-aliasing -fmessage-length=0 -Wp,-D_FORTIFY_SOURCE=2 -DG_DISABLE_DEPRECATED -DG_DISABLE_SINGLE_INCLUDES -DGDK_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_DEPRECATED -DGTK_DISABLE_SINGLE_INCLUDES"
108 fi
109 AC_SUBST(ADDITIONAL_FLAGS)
110
111 PACKAGE_CFLAGS="$PACKAGE_CFLAGS $MENU_CACHE_CFLAGS $ADDITIONAL_FLAGS"
112 PACKAGE_LIBS="$PACKAGE_LIBS $MENU_CACHE_LIBS"
113
114 AC_ARG_ENABLE(man,
115         [AC_HELP_STRING([--enable-man],
116                 [regenerate roff man pages from Docbook @<:@default=no@:>@])],
117         [enable_man="${enableval}"],
118         [enable_man=no]
119 )
120
121 dnl linker tweaking
122 # The function of the link flag --as-needed is to prevent unnecesary linking.
123 # Example: A -> B -> C
124 # Normally, A would link to B and also depend on C, this is of cource
125 # unnecesary. In this situation, however we do need to link to C, so this
126 # must be done explicitly. This flag comes in handy when a library ABI
127 # is changed, minimizing the amount of recompilations needed.
128 AC_MSG_CHECKING([whether $LD accepts --as-needed])
129 case `$LD --as-needed -v 2>&1 </dev/null` in
130 *GNU* | *'with BFD'*)
131     LDFLAGS="$LDFLAGS -Wl,--as-needed"
132     AC_MSG_RESULT([yes])
133     ;;
134 *)
135     AC_MSG_RESULT([no])
136     ;;
137 esac
138
139 dnl linker optimizations
140 AC_MSG_CHECKING([whether $LD accepts -O1])
141 case `$LD -O1 -v 2>&1 </dev/null` in
142 *GNU* | *'with BFD'*)
143   LDFLAGS="$LDFLAGS -Wl,-O1"
144   AC_MSG_RESULT([yes])
145   ;;
146 *)
147   AC_MSG_RESULT([no])
148   ;;
149 esac
150 AC_MSG_CHECKING([whether $LD accepts -Bsymbolic-functions])
151 case `$LD -Bsymbolic-functions -v 2>&1 </dev/null` in
152 *GNU* | *'with BFD'*)
153   LDFLAGS="$LDFLAGS -Wl,-Bsymbolic-functions"
154   AC_MSG_RESULT([yes])
155   ;;
156 *)
157   AC_MSG_RESULT([no])
158   ;;
159 esac
160 AC_MSG_CHECKING([whether $LD accepts --sort-common])
161 case `$LD --sort-common -v 2>&1 </dev/null` in
162 *GNU* | *'with BFD'*)
163   LDFLAGS="$LDFLAGS -Wl,--sort-common"
164   AC_MSG_RESULT([yes])
165   ;;
166 *)
167   AC_MSG_RESULT([no])
168   ;;
169 esac
170
171 dnl FIXME: filter for undefined symbols in plugins
172 # when passing "-z defs" to linker, we would better to make sure
173 # there are no undefined references.  However, we intend not to
174 # fix at the moment since we don't have spin-off libraray containing
175 # the necessary functions.
176 if test ! -z "$LDFLAGS"; then
177     LDFLAGS=`echo "$LDFLAGS" | sed -e 's/-Wl,-z,defs//'`
178 fi
179
180 LXPANEL_MODULE="-avoid-version \
181 -rpath \$(libdir)/lxpanel/plugins \
182 -no-undefined "'-export-symbols-regex "^[[^_]].*"'
183 AC_SUBST(LXPANEL_MODULE)
184
185 AC_ARG_ENABLE([alsa],
186     AS_HELP_STRING([--disable-alsa],
187                     [compile ALSA providers (default: enable)]),
188             compile_alsa=$enableval, compile_alsa="yes")
189 if test x"$compile_alsa" = "xyes"; then
190     AC_CHECK_HEADERS([alsa/asoundlib.h],
191                      [AC_CHECK_LIB([asound],
192                                    [snd_seq_open],
193                                    compile_alsa=yes,compile_alsa=no)],
194                           compile_alsa=no)
195 fi
196 AM_CONDITIONAL(BUILD_ALSA_PLUGINS, test x$compile_alsa = xyes)
197 dnl FIXME: check OSS existence
198 AM_CONDITIONAL(BUILD_OSS_PLUGINS, test x$compile_alsa = xno)
199
200 AC_ARG_ENABLE([plugins-loading],
201     AS_HELP_STRING([--disable-plugins-loading],
202                [disable plugin loading (default: enable)]),
203                plugins_loading=$enableval, plugins_loading="yes")
204
205 AM_CONDITIONAL(BUILD_PLUGIN_LOADER, test x$plugins_loading = xyes)
206
207 if test x"$plugins_loading" = "xno"; then
208     AC_DEFINE(DISABLE_PLUGINS_LOADING, [1], [Disable plugin loading])
209 fi
210
211 dnl Here are plugin listing.
212 plugin_netstatus=
213 plugin_netstat=
214 plugin_volume=
215 plugin_volumealsa=
216 plugin_cpu=
217 plugin_deskno=
218 plugin_batt=
219 plugin_xkb=
220 plugin_kbled=
221 plugin_thermal=
222 plugin_cpufreq=
223 plugin_monitors=
224 plugin_wnckpager=
225 plugin_indicator=
226
227 AC_MSG_CHECKING([which plugins should be built dynamically])
228 AC_ARG_WITH(plugins,
229 [  --with-plugins=<list>  compile dynamic plugins in <list> ]
230 [                         plugins may be comma separated ]
231 [                         'all' builds all plugins (default), 'none' builds none ]
232 [                         plugins prefixed with '-' are not built]
233 [                         Possible plugins are: ]
234 [                         netstatus, netstat, volume, volumealsa, cpu, deskno, batt,]
235 [                         kbled, xkb, thermal, cpufreq, monitors, wnckpager]
236 , plugins="$withval",[plugins="all"])
237
238 if test x"$plugins" != xall -a x"$plugins" != xnone; then
239     if test x"$plugins_loading" = xno; then
240         AC_MSG_ERROR(
241         [--disable-plugins-loading and --with-plugins conflict each other.])
242     fi
243 fi
244
245 ALL_PLUGINS_LIST="netstatus netstat volume volumealsa cpu deskno batt kbled xkb thermal cpufreq monitors wnckpager indicator"
246 AC_SUBST(ALL_PLUGINS_LIST)
247
248 AC_DEFUN([check_plugin_name],[
249     plugin_found=false
250     for name in $ALL_PLUGINS_LIST; do
251         if test x[$1] = x[$name]; then
252             plugin_found=true
253         fi
254     done
255     if test x[$plugin_found] = false; then
256         echo [Unknown plugin $1.]
257         exit 1
258     fi
259 ])
260
261 if test "$plugins" != "none"; then
262     plugins=`echo $plugins | sed 's/,/ /g'`
263     for plugin in $plugins
264     do
265         case "$plugin" in
266             all)
267                 for name in $ALL_PLUGINS_LIST
268                 do
269                     export plugin_$name="$name"
270                 done
271                 ;;
272             -*)
273                 check_plugin_name([${plugin#-}])
274                 export plugin_${plugin#-}=
275                 ;;
276             *)
277                 check_plugin_name([$plugin])
278                 export plugin_$plugin=$plugin
279                 ;;
280         esac
281     done
282     AC_MSG_RESULT($plugins)
283 fi
284
285 dnl FIXME: OSS/ALSA checking
286 if test x"$compile_alsa" = "xno"; then
287     if test ! -z $plugin_volumealsa; then
288         AC_MSG_RESULT([no ALSA headers/libraries found!])
289         plugin_volumealsa=
290     fi
291 else
292     dnl force OSS plugin to <null>
293     plugin_volume=
294 fi
295
296 dnl Exclude indicator support when there is no support.
297 if test x"$indicator_support" = "xno"; then
298     plugin_indicator=
299 fi
300
301 PLUGINS_LIST="\
302     $plugin_netstatus \
303     $plugin_netstat \
304     $plugin_volume \
305     $plugin_volumealsa \
306     $plugin_cpu \
307     $plugin_deskno \
308     $plugin_batt \
309     $plugin_kbled \
310     $plugin_xkb \
311     $plugin_thermal \
312     $plugin_cpufreq \
313     $plugin_monitors \
314     $plugin_wnckpager\
315     $plugin_indicator"
316
317 AC_SUBST(PLUGINS_LIST)
318
319 # Plugin-specific dependencies
320 # nestat
321 if test x"$plugin_netstat" != "x";then
322 AC_CHECK_HEADER([iwlib.h],,
323  AC_MSG_ERROR([netstat plugin requires wireless-tools-devel]))
324 fi
325
326 # Checks for header files.
327 AC_PATH_X
328 AC_HEADER_STDC
329 AC_HEADER_SYS_WAIT
330 AC_CHECK_HEADERS([locale.h stdlib.h string.h sys/time.h unistd.h])
331
332 # Checks for typedefs, structures, and compiler characteristics.
333 AC_C_CONST
334 AC_C_INLINE
335 AC_STRUCT_TM
336
337 # Checks for library functions.
338 AC_FUNC_MALLOC
339 AC_FUNC_MEMCMP
340 AC_TYPE_SIGNAL
341 AC_FUNC_STAT
342 AC_FUNC_STRFTIME
343 AC_CHECK_FUNCS([bzero memset mkdir setlocale strchr])
344
345
346 # Generate po/LINGUAS on the fly rather than relying on translators
347 # to maintain it manually. This also overcome the problem that Transifex
348 # cannot add a language to po/LINGUAS if a new po file is submitted.
349 rm -f $srcdir/po/LINGUAS
350 for po_file in `ls $srcdir/po/*.po | sort`;
351 do
352     lang=`echo "$po_file" | sed "s|.*/po/\(.*\)\.po|\1|g"`
353     echo $lang >> $srcdir/po/LINGUAS
354 done
355
356 GETTEXT_PACKAGE=lxpanel
357 AM_GNU_GETTEXT([external])
358 AM_GNU_GETTEXT_VERSION(0.14.1)
359 AC_SUBST(GETTEXT_PACKAGE)
360 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
361
362 AM_GLIB_GNU_GETTEXT
363
364 if test x"$enable_man" = x"yes"; then
365         AC_PATH_PROG([XSLTPROC], [xsltproc])
366         if test -z "$XSLTPROC"; then
367                 enable_man=no
368         fi
369
370         dnl check for DocBook DTD and stylesheets in the local catalog.
371         JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
372                 [DocBook XML DTD V4.1.2], [], enable_man=no)
373         JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
374                 [DocBook XSL Stylesheets >= 1.70.1], [], enable_man=no)
375 fi
376
377 AM_CONDITIONAL(ENABLE_REGENERATE_MAN, test "x$enable_man" != "xno")
378
379 AC_ARG_ENABLE(debug,
380     [AC_HELP_STRING([--enable-debug],
381         [enable debug support @<:@default=no@:>@])],
382     [enable_debug="${enableval}"],
383     [enable_debug=no]
384 )
385 if test "$enable_debug" = "yes"; then
386     # turn on debug and disable optimization
387     CPPFLAGS="$CPPFLAGS -DG_ENABLE_DEBUG -O0 -g"
388     case "$CC" in
389     gcc*)
390         CPPFLAGS="$CPPFLAGS -Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers -Werror=implicit-function-declaration"
391         ;;
392     *)
393         ;;
394     esac
395     dnl Be more strict on portability
396     #CPPFLAGS="$CPPFLAGS -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=700"
397 else
398     # turn off glib debug checks
399     CPPFLAGS="$CPPFLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
400 fi
401
402 AC_CONFIG_FILES([
403     lxpanel.pc
404     Makefile
405     src/Makefile
406     src/plugins/Makefile
407     src/plugins/netstatus/Makefile
408     src/plugins/netstat/Makefile
409     src/plugins/volume/Makefile
410     src/plugins/volumealsa/Makefile
411     src/plugins/cpu/Makefile
412     src/plugins/deskno/Makefile
413     src/plugins/batt/Makefile
414     src/plugins/kbled/Makefile
415     src/plugins/xkb/Makefile
416     src/plugins/thermal/Makefile
417     src/plugins/cpufreq/Makefile
418     src/plugins/monitors/Makefile
419     src/plugins/wnckpager/Makefile
420     src/plugins/indicator/Makefile
421     po/Makefile.in
422     data/Makefile
423     data/default/panels/panel
424     data/two_panels/panels/top
425     data/two_panels/panels/bottom
426     man/Makefile
427 ])
428 AC_OUTPUT
429
430 echo
431 echo lxpanel ......................... : Version $VERSION
432 echo
433 echo Prefix........................... : $prefix
434 if test x$plugins_loading = xyes; then
435 echo Building dynamic plugins:
436     if test x"$plugin_netstatus" != x; then
437         AC_MSG_RESULT([    netstatus - Monitor networking status])
438     fi
439     if test x"$plugin_netstat" != x; then
440         AC_MSG_RESULT([    netstat - Monitor networking status])
441     fi
442     if test x"$plugin_volume" != x; then
443         AC_MSG_RESULT([    volume - Display and adjust volume of sound card for OSS])
444     fi
445     if test x"$plugin_volumealsa" != x; then
446         AC_MSG_RESULT([    volumealsa - Display and adjust volume of sound card for ALSA])
447     fi
448     if test x"$plugin_cpu" != x; then
449         AC_MSG_RESULT([    cpu - Display CPU loading])
450     fi
451     if test x"$plugin_deskno" != x; then
452         AC_MSG_RESULT([    deskno - Display desktop number])
453     fi
454     if test x"$plugin_batt" != x; then
455         AC_MSG_RESULT([    batt - Monitor battery status])
456     fi
457     if test x"$plugin_kbled" != x; then
458         AC_MSG_RESULT([    kbled - Indicator for CapsLock, NumLock, and ScrLock])
459     fi
460     if test x"$plugin_xkb" != x; then
461         AC_MSG_RESULT([    xkb - Keyboard layout handler])
462     fi
463     if test x"$plugin_thermal" != x; then
464         AC_MSG_RESULT([    thermal - Temperature monitor])
465     fi
466     if test x"$plugin_cpufreq" != x; then
467         AC_MSG_RESULT([    cpufreq - CpuFreq frontend])
468     fi
469     if test x"$plugin_monitors" != x; then
470         AC_MSG_RESULT([    monitors - Monitors for CPU & RAM])
471     fi
472     if test x"$plugin_wnckpager" != x; then
473         AC_MSG_RESULT([    wnckpager - Pager which support openbox and compiz])
474     fi
475     if test x"$plugin_indicator" != x; then
476         AC_MSG_RESULT([    indicator - Indicator support])
477     fi
478 else
479 echo Dynamic loader for plugins....... : disabled.
480 fi
481
482 echo
483 echo 'LXPanel requires menu-cache and lxmenu-data packages since'
484 echo 'version 0.4.0. Please make sure they are correctly installed.'
485 echo 'Otherwise, you will not be able to use applications menu.'
486 echo
487