Reworked man page generation.
[lxde/lxpanel.git] / configure.ac
1 AC_PREREQ(2.53)
2 AC_INIT(lxpanel, 0.4.1, http://lxde.org/)
3 AM_INIT_AUTOMAKE
4 AC_CONFIG_SRCDIR([src/bg.c])
5 AC_CONFIG_HEADER([config.h])
6
7 # Force to dynamic
8 AC_DISABLE_STATIC
9
10 # Checks for programs.
11 AC_PROG_CC
12 AC_PROG_INSTALL
13 AC_PROG_LN_S
14 AC_PROG_LIBTOOL
15 AC_PROG_INTLTOOL(, [no-xml])
16 AM_PROG_CC_C_O
17
18 # Checks for libraries.
19 pkg_modules="gtk+-2.0 >= 2.12.0 \
20              gthread-2.0"
21 #             libstartup-notification-1.0"
22 PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
23 AC_SUBST(PACKAGE_CFLAGS)
24 AC_SUBST(PACKAGE_LIBS)
25
26 pkg_modules="libmenu-cache"
27 PKG_CHECK_MODULES(MENU_CACHE, [$pkg_modules],
28                   enable_menu_cache=yes, enable_menu_cache=no)
29 if test x"$enable_menu_cache" = "xno"; then
30         AC_WARN([No libmenu-cache found.  All menu related routines are not built.])
31         AC_DEFINE(DISABLE_MENU, [1], [Disable menu related routines])
32 fi
33 AC_SUBST(MENU_CACHE_CFLAGS)
34 AC_SUBST(MENU_CACHE_LIBS)
35 AM_CONDITIONAL(ENABLE_MENU_CACHE, test x"$enable_menu_cache" = x"yes") 
36
37 PACKAGE_CFLAGS="$PACKAGE_CFLAGS $MENU_CACHE_CFLAGS"
38 PACKAGE_LIBS="$PACKAGE_LIBS $MENU_CACHE_LIBS"
39
40 AC_ARG_ENABLE(man,
41         [AC_HELP_STRING([--enable-man],
42                 [regenerate roff man pages from Docbook @<:@default=no@:>@])],
43         [enable_man="${enableval}"],
44         [enable_man=no]
45 )
46
47 AC_ARG_ENABLE([cast-checks],
48     AS_HELP_STRING([--enable-cast-checks],
49                [enable Glib casting checks (default: disable)]),
50                cast_checks=$enableval, cast_checks="no")
51 G_CAST_CHECKS=""
52 if test x"$cast_checks" = "xno"; then
53     G_CAST_CHECKS="-DG_DISABLE_CAST_CHECKS"
54 fi
55 AC_SUBST(G_CAST_CHECKS)
56
57 dnl linker tweaking
58 # The function of the link flag --as-needed is to prevent unnecesary linking.
59 # Example: A -> B -> C
60 # Normally, A would link to B and also depend on C, this is of cource
61 # unnecesary. In this situation, however we do need to link to C, so this
62 # must be done explicitly. This flag comes in handy when a library ABI
63 # is changed, minimizing the amount of recompilations needed.
64 AC_MSG_CHECKING([whether $LD accepts --as-needed])
65 case `$LD --as-needed -v 2>&1 </dev/null` in
66 *GNU* | *'with BFD'*)
67     LDFLAGS="$LDFLAGS -Wl,--as-needed"
68     AC_MSG_RESULT([yes])
69     ;;
70 *)
71     AC_MSG_RESULT([no])
72     ;;
73 esac
74
75 dnl linker optimizations
76 AC_MSG_CHECKING([whether $LD accepts -O1])
77 case `$LD -O1 -v 2>&1 </dev/null` in
78 *GNU* | *'with BFD'*)
79   LDFLAGS="$LDFLAGS -Wl,-O1"
80   AC_MSG_RESULT([yes])
81   ;;
82 *)
83   AC_MSG_RESULT([no])
84   ;;
85 esac
86 AC_MSG_CHECKING([whether $LD accepts -Bsymbolic-functions])
87 case `$LD -Bsymbolic-functions -v 2>&1 </dev/null` in
88 *GNU* | *'with BFD'*)
89   LDFLAGS="$LDFLAGS -Wl,-Bsymbolic-functions"
90   AC_MSG_RESULT([yes])
91   ;;
92 *)
93   AC_MSG_RESULT([no])
94   ;;
95 esac
96 AC_MSG_CHECKING([whether $LD accepts --sort-common])
97 case `$LD --sort-common -v 2>&1 </dev/null` in
98 *GNU* | *'with BFD'*)
99   LDFLAGS="$LDFLAGS -Wl,--sort-common"
100   AC_MSG_RESULT([yes])
101   ;;
102 *)
103   AC_MSG_RESULT([no])
104   ;;
105 esac
106
107 dnl FIXME: filter for undefined symbols in plugins
108 # when passing "-z defs" to linker, we would better to make sure
109 # there are no undefined references.  However, we intend not to
110 # fix at the moment since we don't have spin-off libraray containing
111 # the necessary functions.
112 if test ! -z "$LDFLAGS"; then
113     LDFLAGS=`echo "$LDFLAGS" | sed -e 's/-Wl,-z,defs//'`
114 fi
115
116 LXPANEL_MODULE="-avoid-version \
117 -rpath \$(libdir)/lxpanel/plugins \
118 -no-undefined "'-export-symbols-regex "^[[^_]].*"'
119 AC_SUBST(LXPANEL_MODULE)
120
121 AC_ARG_ENABLE([alsa],
122     AS_HELP_STRING([--disable-alsa],
123                     [compile ALSA providers (default: enable)]),
124             compile_alsa=$enableval, compile_alsa="yes")
125 if test x"$compile_alsa" = "xyes"; then
126     AC_CHECK_HEADERS([alsa/asoundlib.h],
127                      [AC_CHECK_LIB([asound],
128                                    [snd_seq_open],
129                                    compile_alsa=yes,compile_alsa=no)],
130                           compile_alsa=no)
131 fi
132 AM_CONDITIONAL(BUILD_ALSA_PLUGINS, test x$compile_alsa = xyes)
133 dnl FIXME: check OSS existence
134 AM_CONDITIONAL(BUILD_OSS_PLUGINS, test x$compile_alsa = xno)
135
136 # check libiw for netstat plugin
137 AC_ARG_ENABLE([libiw],
138     AS_HELP_STRING([--disable-libiw],
139                     [compile libiw-based netstat plugin (default: disable)]),
140             compile_libiw=$enableval, compile_libiw="no")
141 if test x"$compile_libiw" = "xyes"; then
142     AC_CHECK_HEADERS(iwlib.h,
143                      [AC_CHECK_LIB(iw,
144                                    iw_sockets_open,
145                                    compile_libiw=yes,
146                                    compile_libiw=no)],
147                                    compile_libiw=no)
148 fi
149 AM_CONDITIONAL(BUILD_LIBIW_PLUGINS, test x$compile_libiw = xyes)
150
151 AC_ARG_ENABLE([plugins-loading],
152     AS_HELP_STRING([--disable-plugins-loading],
153                [disable plugin loading (default: enable)]),
154                plugins_loading=$enableval, plugins_loading="yes")
155
156 AM_CONDITIONAL(BUILD_PLUGIN_LOADER, test x$plugins_loading = xyes)
157
158 if test x"$plugins_loading" = "xno"; then
159     AC_DEFINE(DISABLE_PLUGINS_LOADING, [1], [Disable plugin loading])
160 fi
161
162 dnl Here are plugin listing.
163 plugin_netstatus=
164 plugin_netstat=
165 plugin_volume=
166 plugin_volumealsa=
167 plugin_cpu=
168 plugin_deskno=
169 plugin_batt=
170 plugin_xkb=
171 plugin_kbled=
172 plugin_thermal=
173
174 AC_MSG_CHECKING([which plugins should be built dynamically])
175 AC_ARG_WITH(plugins,
176 [  --with-plugins=<list>  compile dynamic plugins in <list> ]
177 [                         plugins may be comma separated ]
178 [                         'all' builds all plugins (default), 'none' builds none ]
179 [                         Possible plugins are: ]
180 [                         netstatus, netstat, volume, volumealsa, cpu, deskno, batt, kbled, xkb, thermal], plugins="$withval",[plugins="all"])
181
182 if test x"$plugins" != xall -a x"$plugins" != xnone; then
183     if test x"$plugins_loading" = xno; then
184         AC_MSG_ERROR(
185         [--disable-plugins-loading and --with-plugins conflict each other.])
186     fi
187 fi
188
189 ALL_PLUGINS_LIST="netstatus netstat volume volumealsa cpu deskno batt kbled xkb thermal"
190 AC_SUBST(ALL_PLUGINS_LIST)
191
192 if test x"$plugins" = xall; then
193 dnl    for name in $ALL_PLUGINS
194 dnl    do
195 dnl        export plugin_$name="$name"
196 dnl    done
197
198     plugin_netstatus=netstatus
199     plugin_netstat=
200     plugin_volume=volume
201     plugin_volumealsa=volumealsa
202     plugin_cpu=cpu
203     plugin_deskno=deskno
204     plugin_batt=batt
205     plugin_kbled=kbled
206     plugin_xkb=
207     plugin_thermal=thermal
208
209     AC_MSG_RESULT(all)
210 else
211     if test "$plugins" != "none"; then
212         plugins=`echo $plugins | sed 's/,/ /g'`
213         for plugin in $plugins
214         do
215         case "$plugin" in
216             netstatus)
217                 plugin_netstatus=netstatus
218                 ;;
219             netstat)
220                 plugin_netstat=netstat
221                 ;;
222             volume)
223                 plugin_volume=volume
224                 ;;
225             volumealsa)
226                 plugin_volumealsa=volumealsa
227                 ;;
228             cpu)
229                 plugin_cpu=cpu
230                 ;;
231             deskno)
232                 plugin_deskno=deskno
233                 ;;
234             batt)
235                 plugin_batt=batt
236                 ;;
237             kbled)
238                 plugin_kbled=kbled
239                 ;;
240             xkb)
241                 plugin_xkb=xkb
242                 ;;
243             thermal)
244                 plugin_thermal=thermal
245                 ;;
246             *)
247                 echo "Unknown plugin $plugin."
248                 exit 1
249                 ;;
250         esac
251         done
252         AC_MSG_RESULT($plugins)
253     fi
254 fi
255
256 dnl FIXME: OSS/ALSA checking
257 if test x"$compile_alsa" = "xno"; then
258     if test ! -z $plugin_volumealsa; then
259         AC_MSG_RESULT([no ALSA headers/libraries found!])
260         plugin_volumealsa=
261     fi
262 else
263     dnl force OSS plugin to <null>
264     plugin_volume=
265 fi
266 if test x"$compile_libiw" = "xno"; then
267    if test ! -z $plugin_netstat; then
268        AC_MSG_RESULT([no libiw headers/libraries found!])
269    fi
270    plugin_netstat=
271 fi
272 PLUGINS_LIST="\
273     $plugin_netstatus \
274     $plugin_netstat \
275     $plugin_volume \
276     $plugin_volumealsa \
277     $plugin_cpu \
278     $plugin_deskno \
279     $plugin_batt \
280     $plugin_kbled \
281     $plugin_xkb \
282     $plugin_thermal"
283
284 AC_SUBST(PLUGINS_LIST)
285
286
287 # Checks for header files.
288 AC_PATH_X
289 AC_HEADER_STDC
290 AC_HEADER_SYS_WAIT
291 AC_CHECK_HEADERS([locale.h stdlib.h string.h sys/time.h unistd.h])
292
293 # Checks for typedefs, structures, and compiler characteristics.
294 AC_C_CONST
295 AC_C_INLINE
296 AC_STRUCT_TM
297
298 # Checks for library functions.
299 AC_FUNC_MALLOC
300 AC_FUNC_MEMCMP
301 AC_TYPE_SIGNAL
302 AC_FUNC_STAT
303 AC_FUNC_STRFTIME
304 AC_CHECK_FUNCS([bzero memset mkdir setlocale strchr])
305
306
307 GETTEXT_PACKAGE=lxpanel
308 #AM_GNU_GETTEXT([external])
309 AM_GNU_GETTEXT_VERSION(0.14.1)
310 AC_SUBST(GETTEXT_PACKAGE)
311 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
312
313 ALL_LINGUAS="af ar cs da de es et eu fa fi fr gl hu hr id it ja ko lt ml ms nb nl nn pl ps pt pt_BR ru sk sl sv tr uk ur ur_PK vi zh_CN zh_TW"
314 AM_GLIB_GNU_GETTEXT
315
316 if test x"$enable_man" = x"yes"; then
317         AC_PATH_PROG([XSLTPROC], [xsltproc])
318         if test -z "$XSLTPROC"; then
319                 enable_man=no
320         fi
321
322         dnl check for DocBook DTD and stylesheets in the local catalog.
323         JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
324                 [DocBook XML DTD V4.1.2], [], enable_man=no)
325         JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
326                 [DocBook XSL Stylesheets >= 1.70.1], [], enable_man=no)
327 fi
328
329 AM_CONDITIONAL(ENABLE_REGENERATE_MAN, test "x$enable_man" != "xno")
330
331 AC_CONFIG_FILES([
332     lxpanel.pc
333     Makefile
334     src/Makefile
335     src/plugins/Makefile
336     src/plugins/netstatus/Makefile
337     src/plugins/netstat/Makefile
338     src/plugins/volume/Makefile
339     src/plugins/volumealsa/Makefile
340     src/plugins/cpu/Makefile
341     src/plugins/deskno/Makefile
342     src/plugins/batt/Makefile
343     src/plugins/kbled/Makefile
344     src/plugins/xkb/Makefile
345     src/plugins/thermal/Makefile
346     po/Makefile.in
347     data/Makefile
348     data/default/panels/panel
349     man/Makefile
350 ])
351 AC_OUTPUT
352
353 echo
354 echo lxpanel ......................... : Version $VERSION
355 echo
356 echo Prefix........................... : $prefix
357 if test x$plugins_loading = xyes; then
358 echo Building dynamic plugins:
359     if test x"$plugin_netstatus" != x; then
360         AC_MSG_RESULT([    netstatus - Monitor networking status])
361     fi
362     if test x"$plugin_netstat" != x; then
363         AC_MSG_RESULT([    netstat - Monitor networking status (Linux Only)])
364     fi
365     if test x"$plugin_volume" != x; then
366         AC_MSG_RESULT([    volume - Display and adjust volume of sound card])
367     fi
368     if test x"$plugin_volumealsa" != x; then
369         AC_MSG_RESULT([    volumealsa - Display and adjust volume of sound card for ALSA])
370     fi
371     if test x"$plugin_cpu" != x; then
372         AC_MSG_RESULT([    cpu - Display CPU loading])
373     fi
374     if test x"$plugin_deskno" != x; then
375         AC_MSG_RESULT([    deskno - Display desktop number])
376     fi
377     if test x"$plugin_batt" != x; then
378         AC_MSG_RESULT([    batt - Monitor battery status])
379     fi
380     if test x"$plugin_kbled" != x; then
381         AC_MSG_RESULT([    kbled - Indicator for CapsLock, NumLock, and ScrLock])
382     fi
383     if test x"$plugin_xkb" != x; then
384         AC_MSG_RESULT([    xkb - Keyboard layout switcher])
385     fi
386     if test x"$plugin_thermal" != x; then
387         AC_MSG_RESULT([    thermal - Temperature monitor])
388     fi
389 else
390 echo Dynamic loader for plugins....... : disabled.
391 fi
392
393 echo
394 echo 'LXPanel requires menu-cache and lxmenu-data packages since'
395 echo 'version 0.4.0. Please make sure they are correctly installed.'
396 echo 'Otherwise, you will not be able to use applications menu.'
397 echo
398