New lxpanel plugin for temperature monitoring.
[lxde/lxpanel.git] / configure.ac
1 AC_PREREQ(2.53)
2 AC_INIT(lxpanel, 0.3.8.1, http://lxde.org/)
3 AM_INIT_AUTOMAKE
4 AC_CONFIG_SRCDIR([src/bg.c])
5 AC_CONFIG_HEADER([config.h])
6
7 # Force to dynamic
8 AC_DISABLE_STATIC
9
10 # Checks for programs.
11 AC_PROG_CC
12 AC_PROG_INSTALL
13 AC_PROG_LN_S
14 AC_PROG_LIBTOOL
15 AC_PROG_INTLTOOL(, [no-xml])
16
17 # Checks for libraries.
18 pkg_modules="gtk+-2.0 >= 2.6.0 \
19              gthread-2.0"
20 #             libstartup-notification-1.0"
21 PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
22 AC_SUBST(PACKAGE_CFLAGS)
23 AC_SUBST(PACKAGE_LIBS)
24
25 AC_ARG_ENABLE([cast-checks],
26     AS_HELP_STRING([--enable-cast-checks],
27                [enable Glib casting checks (default: disable)]),
28                cast_checks=$enableval, cast_checks="no")
29 G_CAST_CHECKS=""
30 if test x"$cast_checks" = "xno"; then
31     G_CAST_CHECKS="-DG_DISABLE_CAST_CHECKS"
32 fi
33 AC_SUBST(G_CAST_CHECKS)
34
35 dnl linker tweaking
36 # The function of the link flag --as-needed is to prevent unnecesary linking.
37 # Example: A -> B -> C
38 # Normally, A would link to B and also depend on C, this is of cource
39 # unnecesary. In this situation, however we do need to link to C, so this
40 # must be done explicitly. This flag comes in handy when a library ABI
41 # is changed, minimizing the amount of recompilations needed.
42 AC_MSG_CHECKING([whether $LD accepts --as-needed])
43 case `$LD --as-needed -v 2>&1 </dev/null` in
44 *GNU* | *'with BFD'*)
45     LDFLAGS="$LDFLAGS -Wl,--as-needed"
46     AC_MSG_RESULT([yes])
47     ;;
48 *)
49     AC_MSG_RESULT([no])
50     ;;
51 esac
52
53 dnl linker optimizations
54 AC_MSG_CHECKING([whether $LD accepts -O1])
55 case `$LD -O1 -v 2>&1 </dev/null` in
56 *GNU* | *'with BFD'*)
57   LDFLAGS="$LDFLAGS -Wl,-O1"
58   AC_MSG_RESULT([yes])
59   ;;
60 *)
61   AC_MSG_RESULT([no])
62   ;;
63 esac
64 AC_MSG_CHECKING([whether $LD accepts -Bsymbolic-functions])
65 case `$LD -Bsymbolic-functions -v 2>&1 </dev/null` in
66 *GNU* | *'with BFD'*)
67   LDFLAGS="$LDFLAGS -Wl,-Bsymbolic-functions"
68   AC_MSG_RESULT([yes])
69   ;;
70 *)
71   AC_MSG_RESULT([no])
72   ;;
73 esac
74 AC_MSG_CHECKING([whether $LD accepts --sort-common])
75 case `$LD --sort-common -v 2>&1 </dev/null` in
76 *GNU* | *'with BFD'*)
77   LDFLAGS="$LDFLAGS -Wl,--sort-common"
78   AC_MSG_RESULT([yes])
79   ;;
80 *)
81   AC_MSG_RESULT([no])
82   ;;
83 esac
84
85 dnl FIXME: filter for undefined symbols in plugins
86 # when passing "-z defs" to linker, we would better to make sure
87 # there are no undefined references.  However, we intend not to
88 # fix at the moment since we don't have spin-off libraray containing
89 # the necessary functions.
90 if test ! -z "$LDFLAGS"; then
91     LDFLAGS=`echo "$LDFLAGS" | sed -e 's/-Wl,-z,defs//'`
92 fi
93
94 LXPANEL_MODULE="-avoid-version \
95 -rpath \$(libdir)/lxpanel/plugins \
96 -no-undefined "'-export-symbols-regex "^[[^_]].*"'
97 AC_SUBST(LXPANEL_MODULE)
98
99 AC_ARG_ENABLE([alsa],
100     AS_HELP_STRING([--disable-alsa],
101                     [compile ALSA providers (default: enable)]),
102             compile_alsa=$enableval, compile_alsa="yes")
103 if test x"$compile_alsa" = "xyes"; then
104     AC_CHECK_HEADERS([alsa/asoundlib.h],
105                      [AC_CHECK_LIB([asound],
106                                    [snd_seq_open],
107                                    compile_alsa=yes,compile_alsa=no)],
108                           compile_alsa=no)
109 fi
110 AM_CONDITIONAL(BUILD_ALSA_PLUGINS, test x$compile_alsa = xyes)
111 dnl FIXME: check OSS existence
112 AM_CONDITIONAL(BUILD_OSS_PLUGINS, test x$compile_alsa = xno)
113
114 # check libiw for netstat plugin
115 AC_ARG_ENABLE([libiw],
116     AS_HELP_STRING([--disable-libiw],
117                     [compile libiw-based netstat plugin (default: enable)]),
118             compile_libiw=$enableval, compile_libiw="yes")
119 if test x"$compile_libiw" = "xyes"; then
120     AC_CHECK_HEADERS(iwlib.h,
121                      [AC_CHECK_LIB(iw,
122                                    iw_sockets_open,
123                                    compile_libiw=yes,
124                                    compile_libiw=no)],
125                                    compile_libiw=no)
126 fi
127 AM_CONDITIONAL(BUILD_LIBIW_PLUGINS, test x$compile_libiw = xyes)
128
129 AC_ARG_ENABLE([plugins-loading],
130     AS_HELP_STRING([--disable-plugins-loading],
131                [disable plugin loading (default: enable)]),
132                plugins_loading=$enableval, plugins_loading="yes")
133
134 AM_CONDITIONAL(BUILD_PLUGIN_LOADER, test x$plugins_loading = xyes)
135
136 if test x"$plugins_loading" = "xno"; then
137     AC_DEFINE(DISABLE_PLUGINS_LOADING, [1], [Disable plugin loading])
138 fi
139
140 dnl Here are plugin listing.
141 plugin_netstatus=
142 plugin_netstat=
143 plugin_volume=
144 plugin_volumealsa=
145 plugin_cpu=
146 plugin_deskno=
147 plugin_batt=
148 plugin_xkb=
149 plugin_kbled=
150 plugin_thermal=thermal
151
152 AC_MSG_CHECKING([which plugins should be built dynamically])
153 AC_ARG_WITH(plugins,
154 [  --with-plugins=<list>  compile dynamic plugins in <list> ]
155 [                         plugins may be comma separated ]
156 [                         'all' builds all plugins (default), 'none' builds none ]
157 [                         Possible plugins are: ]
158 [                         netstatus, netstat, volume, volumealsa, cpu, deskno, batt, kbled, xkb, thermal], plugins="$withval",[plugins="all"])
159
160 if test x"$plugins" != xall -a x"$plugins" != xnone; then
161     if test x"$plugins_loading" = xno; then
162         AC_MSG_ERROR(
163         [--disable-plugins-loading and --with-plugins conflict each other.])
164     fi
165 fi
166
167 ALL_PLUGINS_LIST="netstatus netstat volume volumealsa cpu deskno batt kbled xkb thermal"
168 AC_SUBST(ALL_PLUGINS_LIST)
169
170 if test x"$plugins" = xall; then
171 dnl    for name in $ALL_PLUGINS
172 dnl    do
173 dnl        export plugin_$name="$name"
174 dnl    done
175
176     plugin_netstatus=netstatus
177     plugin_netstat=netstat
178     plugin_volume=volume
179     plugin_volumealsa=volumealsa
180     plugin_cpu=cpu
181     plugin_deskno=deskno
182     plugin_batt=batt
183     plugin_kbled=kbled
184     plugin_xkb=
185     plugin_thermal=thermal
186
187     AC_MSG_RESULT(all)
188 else
189     if test "$plugins" != "none"; then
190         plugins=`echo $plugins | sed 's/,/ /g'`
191         for plugin in $plugins
192         do
193         case "$plugin" in
194             netstatus)
195                 plugin_netstatus=netstatus
196                 ;;
197             netstat)
198                 plugin_netstat=netstat
199                 ;;
200             volume)
201                 plugin_volume=volume
202                 ;;
203             volumealsa)
204                 plugin_volumealsa=volumealsa
205                 ;;
206             cpu)
207                 plugin_cpu=cpu
208                 ;;
209             deskno)
210                 plugin_deskno=deskno
211                 ;;
212             batt)
213                 plugin_batt=batt
214                 ;;
215             kbled)
216                 plugin_kbled=kbled
217                 ;;
218             xkb)
219                 plugin_xkb=xkb
220                 ;;
221             thermal)
222                 plugin_thermal=thermal
223                 ;;
224             *)
225                 echo "Unknown plugin $plugin."
226                 exit 1
227                 ;;
228         esac
229         done
230         AC_MSG_RESULT($plugins)
231     fi
232 fi
233
234 dnl FIXME: OSS/ALSA checking
235 if test x"$compile_alsa" = "xno"; then
236     if test ! -z $plugin_volumealsa; then
237         AC_MSG_RESULT([no ALSA headers/libraries found!])
238         plugin_volumealsa=
239     fi
240 else
241     dnl force OSS plugin to <null>
242     plugin_volume=
243 fi
244 if test x"$compile_libiw" = "xno"; then
245    if test ! -z $plugin_netstat; then
246        AC_MSG_RESULT([no libiw headers/libraries found!])
247    fi
248    plugin_netstat=
249 fi
250 PLUGINS_LIST="\
251     $plugin_netstatus \
252     $plugin_netstat \
253     $plugin_volume \
254     $plugin_volumealsa \
255     $plugin_cpu \
256     $plugin_deskno \
257     $plugin_batt \
258     $plugin_kbled \
259     $plugin_xkb \
260     $plugin_thermal"
261
262 AC_SUBST(PLUGINS_LIST)
263
264
265 # Checks for header files.
266 AC_PATH_X
267 AC_HEADER_STDC
268 AC_HEADER_SYS_WAIT
269 AC_CHECK_HEADERS([locale.h stdlib.h string.h sys/time.h unistd.h])
270
271 # Checks for typedefs, structures, and compiler characteristics.
272 AC_C_CONST
273 AC_C_INLINE
274 AC_STRUCT_TM
275
276 # Checks for library functions.
277 AC_FUNC_MALLOC
278 AC_FUNC_MEMCMP
279 AC_TYPE_SIGNAL
280 AC_FUNC_STAT
281 AC_FUNC_STRFTIME
282 AC_CHECK_FUNCS([bzero memset mkdir setlocale strchr])
283
284
285 GETTEXT_PACKAGE=lxpanel
286 #AM_GNU_GETTEXT([external])
287 AM_GNU_GETTEXT_VERSION(0.14.1)
288 AC_SUBST(GETTEXT_PACKAGE)
289 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
290
291 ALL_LINGUAS="zh_TW ko hu sk pl fr pt_BR fi de es"
292 AM_GLIB_GNU_GETTEXT
293
294 AC_CONFIG_FILES([
295     Makefile
296     src/Makefile
297     src/plugins/Makefile
298     src/plugins/netstatus/Makefile
299     src/plugins/netstat/Makefile
300     src/plugins/volume/Makefile
301     src/plugins/volumealsa/Makefile
302     src/plugins/cpu/Makefile
303     src/plugins/deskno/Makefile
304     src/plugins/batt/Makefile
305     src/plugins/kbled/Makefile
306     src/plugins/xkb/Makefile
307     src/plugins/thermal/Makefile
308     po/Makefile.in
309     data/Makefile
310     data/default/panels/panel
311     man/Makefile
312 ])
313 AC_OUTPUT
314
315 echo
316 echo lxpanel ......................... : Version $VERSION
317 echo
318 echo Prefix........................... : $prefix
319 if test x$plugins_loading = xyes; then
320 echo Building dynamic plugins:
321     if test x"$plugin_netstatus" != x; then
322         AC_MSG_RESULT([    netstatus - Monitor networking status])
323     fi
324     if test x"$plugin_netstat" != x; then
325         AC_MSG_RESULT([    netstat - Monitor networking status (Linux Only)])
326     fi
327     if test x"$plugin_volume" != x; then
328         AC_MSG_RESULT([    volume - Display and adjust volume of sound card])
329     fi
330     if test x"$plugin_volumealsa" != x; then
331         AC_MSG_RESULT([    volumealsa - Display and adjust volume of sound card for ALSA])
332     fi
333     if test x"$plugin_cpu" != x; then
334         AC_MSG_RESULT([    cpu - Display CPU loading])
335     fi
336     if test x"$plugin_deskno" != x; then
337         AC_MSG_RESULT([    deskno - Display desktop number])
338     fi
339     if test x"$plugin_batt" != x; then
340         AC_MSG_RESULT([    batt - Monitor battery status])
341     fi
342     if test x"$plugin_kbled" != x; then
343         AC_MSG_RESULT([    kbled - Indicator for CapsLock, NumLock, and ScrLock])
344     fi
345     if test x"$plugin_xkb" != x; then
346         AC_MSG_RESULT([    xkb - Keyboard layout switcher])
347     fi
348     if test x"$plugin_thermal" != x; then
349         AC_MSG_RESULT([    thermal - Temperature monitor])
350     fi
351 else
352 echo Dynamic loader for plugins....... : disabled.
353 fi