Save glade files in GtkBuilder format directly with glade >= 3.6 and remove gtk-build...
[lxde/lxpanel.git] / configure.ac
1 AC_PREREQ(2.53)
2 AC_INIT(lxpanel, 0.4.1, http://lxde.org/)
3 AM_INIT_AUTOMAKE
4 AC_CONFIG_SRCDIR([src/bg.c])
5 AC_CONFIG_HEADER([config.h])
6
7 # Force to dynamic
8 AC_DISABLE_STATIC
9
10 # Checks for programs.
11 AC_PROG_CC
12 AC_PROG_INSTALL
13 AC_PROG_LN_S
14 AC_PROG_LIBTOOL
15 AC_PROG_INTLTOOL(, [no-xml])
16 AM_PROG_CC_C_O
17
18 # Checks for libraries.
19 pkg_modules="gtk+-2.0 >= 2.12.0 \
20              gthread-2.0"
21 #             libstartup-notification-1.0"
22 PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
23 AC_SUBST(PACKAGE_CFLAGS)
24 AC_SUBST(PACKAGE_LIBS)
25
26 pkg_modules="libmenu-cache"
27 PKG_CHECK_MODULES(MENU_CACHE, [$pkg_modules],
28                   enable_menu_cache=yes, enable_menu_cache=no)
29 if test x"$enable_menu_cache" = "xno"; then
30         AC_WARN([No libmenu-cache found.  All menu related routines are not built.])
31         AC_DEFINE(DISABLE_MENU, [1], [Disable menu related routines])
32 fi
33 AC_SUBST(MENU_CACHE_CFLAGS)
34 AC_SUBST(MENU_CACHE_LIBS)
35 AM_CONDITIONAL(ENABLE_MENU_CACHE, test x"$enable_menu_cache" = x"yes") 
36
37 PACKAGE_CFLAGS="$PACKAGE_CFLAGS $MENU_CACHE_CFLAGS"
38 PACKAGE_LIBS="$PACKAGE_LIBS $MENU_CACHE_LIBS"
39
40 AC_ARG_ENABLE([cast-checks],
41     AS_HELP_STRING([--enable-cast-checks],
42                [enable Glib casting checks (default: disable)]),
43                cast_checks=$enableval, cast_checks="no")
44 G_CAST_CHECKS=""
45 if test x"$cast_checks" = "xno"; then
46     G_CAST_CHECKS="-DG_DISABLE_CAST_CHECKS"
47 fi
48 AC_SUBST(G_CAST_CHECKS)
49
50 dnl linker tweaking
51 # The function of the link flag --as-needed is to prevent unnecesary linking.
52 # Example: A -> B -> C
53 # Normally, A would link to B and also depend on C, this is of cource
54 # unnecesary. In this situation, however we do need to link to C, so this
55 # must be done explicitly. This flag comes in handy when a library ABI
56 # is changed, minimizing the amount of recompilations needed.
57 AC_MSG_CHECKING([whether $LD accepts --as-needed])
58 case `$LD --as-needed -v 2>&1 </dev/null` in
59 *GNU* | *'with BFD'*)
60     LDFLAGS="$LDFLAGS -Wl,--as-needed"
61     AC_MSG_RESULT([yes])
62     ;;
63 *)
64     AC_MSG_RESULT([no])
65     ;;
66 esac
67
68 dnl linker optimizations
69 AC_MSG_CHECKING([whether $LD accepts -O1])
70 case `$LD -O1 -v 2>&1 </dev/null` in
71 *GNU* | *'with BFD'*)
72   LDFLAGS="$LDFLAGS -Wl,-O1"
73   AC_MSG_RESULT([yes])
74   ;;
75 *)
76   AC_MSG_RESULT([no])
77   ;;
78 esac
79 AC_MSG_CHECKING([whether $LD accepts -Bsymbolic-functions])
80 case `$LD -Bsymbolic-functions -v 2>&1 </dev/null` in
81 *GNU* | *'with BFD'*)
82   LDFLAGS="$LDFLAGS -Wl,-Bsymbolic-functions"
83   AC_MSG_RESULT([yes])
84   ;;
85 *)
86   AC_MSG_RESULT([no])
87   ;;
88 esac
89 AC_MSG_CHECKING([whether $LD accepts --sort-common])
90 case `$LD --sort-common -v 2>&1 </dev/null` in
91 *GNU* | *'with BFD'*)
92   LDFLAGS="$LDFLAGS -Wl,--sort-common"
93   AC_MSG_RESULT([yes])
94   ;;
95 *)
96   AC_MSG_RESULT([no])
97   ;;
98 esac
99
100 dnl FIXME: filter for undefined symbols in plugins
101 # when passing "-z defs" to linker, we would better to make sure
102 # there are no undefined references.  However, we intend not to
103 # fix at the moment since we don't have spin-off libraray containing
104 # the necessary functions.
105 if test ! -z "$LDFLAGS"; then
106     LDFLAGS=`echo "$LDFLAGS" | sed -e 's/-Wl,-z,defs//'`
107 fi
108
109 LXPANEL_MODULE="-avoid-version \
110 -rpath \$(libdir)/lxpanel/plugins \
111 -no-undefined "'-export-symbols-regex "^[[^_]].*"'
112 AC_SUBST(LXPANEL_MODULE)
113
114 AC_ARG_ENABLE([alsa],
115     AS_HELP_STRING([--disable-alsa],
116                     [compile ALSA providers (default: enable)]),
117             compile_alsa=$enableval, compile_alsa="yes")
118 if test x"$compile_alsa" = "xyes"; then
119     AC_CHECK_HEADERS([alsa/asoundlib.h],
120                      [AC_CHECK_LIB([asound],
121                                    [snd_seq_open],
122                                    compile_alsa=yes,compile_alsa=no)],
123                           compile_alsa=no)
124 fi
125 AM_CONDITIONAL(BUILD_ALSA_PLUGINS, test x$compile_alsa = xyes)
126 dnl FIXME: check OSS existence
127 AM_CONDITIONAL(BUILD_OSS_PLUGINS, test x$compile_alsa = xno)
128
129 # check libiw for netstat plugin
130 AC_ARG_ENABLE([libiw],
131     AS_HELP_STRING([--disable-libiw],
132                     [compile libiw-based netstat plugin (default: disable)]),
133             compile_libiw=$enableval, compile_libiw="no")
134 if test x"$compile_libiw" = "xyes"; then
135     AC_CHECK_HEADERS(iwlib.h,
136                      [AC_CHECK_LIB(iw,
137                                    iw_sockets_open,
138                                    compile_libiw=yes,
139                                    compile_libiw=no)],
140                                    compile_libiw=no)
141 fi
142 AM_CONDITIONAL(BUILD_LIBIW_PLUGINS, test x$compile_libiw = xyes)
143
144 AC_ARG_ENABLE([plugins-loading],
145     AS_HELP_STRING([--disable-plugins-loading],
146                [disable plugin loading (default: enable)]),
147                plugins_loading=$enableval, plugins_loading="yes")
148
149 AM_CONDITIONAL(BUILD_PLUGIN_LOADER, test x$plugins_loading = xyes)
150
151 if test x"$plugins_loading" = "xno"; then
152     AC_DEFINE(DISABLE_PLUGINS_LOADING, [1], [Disable plugin loading])
153 fi
154
155 dnl Here are plugin listing.
156 plugin_netstatus=
157 plugin_netstat=
158 plugin_volume=
159 plugin_volumealsa=
160 plugin_cpu=
161 plugin_deskno=
162 plugin_batt=
163 plugin_xkb=
164 plugin_kbled=
165 plugin_thermal=
166
167 AC_MSG_CHECKING([which plugins should be built dynamically])
168 AC_ARG_WITH(plugins,
169 [  --with-plugins=<list>  compile dynamic plugins in <list> ]
170 [                         plugins may be comma separated ]
171 [                         'all' builds all plugins (default), 'none' builds none ]
172 [                         Possible plugins are: ]
173 [                         netstatus, netstat, volume, volumealsa, cpu, deskno, batt, kbled, xkb, thermal], plugins="$withval",[plugins="all"])
174
175 if test x"$plugins" != xall -a x"$plugins" != xnone; then
176     if test x"$plugins_loading" = xno; then
177         AC_MSG_ERROR(
178         [--disable-plugins-loading and --with-plugins conflict each other.])
179     fi
180 fi
181
182 ALL_PLUGINS_LIST="netstatus netstat volume volumealsa cpu deskno batt kbled xkb thermal"
183 AC_SUBST(ALL_PLUGINS_LIST)
184
185 if test x"$plugins" = xall; then
186 dnl    for name in $ALL_PLUGINS
187 dnl    do
188 dnl        export plugin_$name="$name"
189 dnl    done
190
191     plugin_netstatus=netstatus
192     plugin_netstat=
193     plugin_volume=volume
194     plugin_volumealsa=volumealsa
195     plugin_cpu=cpu
196     plugin_deskno=deskno
197     plugin_batt=batt
198     plugin_kbled=kbled
199     plugin_xkb=
200     plugin_thermal=thermal
201
202     AC_MSG_RESULT(all)
203 else
204     if test "$plugins" != "none"; then
205         plugins=`echo $plugins | sed 's/,/ /g'`
206         for plugin in $plugins
207         do
208         case "$plugin" in
209             netstatus)
210                 plugin_netstatus=netstatus
211                 ;;
212             netstat)
213                 plugin_netstat=netstat
214                 ;;
215             volume)
216                 plugin_volume=volume
217                 ;;
218             volumealsa)
219                 plugin_volumealsa=volumealsa
220                 ;;
221             cpu)
222                 plugin_cpu=cpu
223                 ;;
224             deskno)
225                 plugin_deskno=deskno
226                 ;;
227             batt)
228                 plugin_batt=batt
229                 ;;
230             kbled)
231                 plugin_kbled=kbled
232                 ;;
233             xkb)
234                 plugin_xkb=xkb
235                 ;;
236             thermal)
237                 plugin_thermal=thermal
238                 ;;
239             *)
240                 echo "Unknown plugin $plugin."
241                 exit 1
242                 ;;
243         esac
244         done
245         AC_MSG_RESULT($plugins)
246     fi
247 fi
248
249 dnl FIXME: OSS/ALSA checking
250 if test x"$compile_alsa" = "xno"; then
251     if test ! -z $plugin_volumealsa; then
252         AC_MSG_RESULT([no ALSA headers/libraries found!])
253         plugin_volumealsa=
254     fi
255 else
256     dnl force OSS plugin to <null>
257     plugin_volume=
258 fi
259 if test x"$compile_libiw" = "xno"; then
260    if test ! -z $plugin_netstat; then
261        AC_MSG_RESULT([no libiw headers/libraries found!])
262    fi
263    plugin_netstat=
264 fi
265 PLUGINS_LIST="\
266     $plugin_netstatus \
267     $plugin_netstat \
268     $plugin_volume \
269     $plugin_volumealsa \
270     $plugin_cpu \
271     $plugin_deskno \
272     $plugin_batt \
273     $plugin_kbled \
274     $plugin_xkb \
275     $plugin_thermal"
276
277 AC_SUBST(PLUGINS_LIST)
278
279
280 # Checks for header files.
281 AC_PATH_X
282 AC_HEADER_STDC
283 AC_HEADER_SYS_WAIT
284 AC_CHECK_HEADERS([locale.h stdlib.h string.h sys/time.h unistd.h])
285
286 # Checks for typedefs, structures, and compiler characteristics.
287 AC_C_CONST
288 AC_C_INLINE
289 AC_STRUCT_TM
290
291 # Checks for library functions.
292 AC_FUNC_MALLOC
293 AC_FUNC_MEMCMP
294 AC_TYPE_SIGNAL
295 AC_FUNC_STAT
296 AC_FUNC_STRFTIME
297 AC_CHECK_FUNCS([bzero memset mkdir setlocale strchr])
298
299
300 GETTEXT_PACKAGE=lxpanel
301 #AM_GNU_GETTEXT([external])
302 AM_GNU_GETTEXT_VERSION(0.14.1)
303 AC_SUBST(GETTEXT_PACKAGE)
304 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
305
306 ALL_LINGUAS="af ar cs da de es et eu fa fi fr gl hu hr id it ja ko lt ml ms nb nl nn pl ps pt pt_BR ru sk sl sv tr uk ur ur_PK vi zh_CN zh_TW"
307 AM_GLIB_GNU_GETTEXT
308
309 AC_CONFIG_FILES([
310     lxpanel.pc
311     Makefile
312     src/Makefile
313     src/plugins/Makefile
314     src/plugins/netstatus/Makefile
315     src/plugins/netstat/Makefile
316     src/plugins/volume/Makefile
317     src/plugins/volumealsa/Makefile
318     src/plugins/cpu/Makefile
319     src/plugins/deskno/Makefile
320     src/plugins/batt/Makefile
321     src/plugins/kbled/Makefile
322     src/plugins/xkb/Makefile
323     src/plugins/thermal/Makefile
324     po/Makefile.in
325     data/Makefile
326     data/default/panels/panel
327     man/Makefile
328 ])
329 AC_OUTPUT
330
331 echo
332 echo lxpanel ......................... : Version $VERSION
333 echo
334 echo Prefix........................... : $prefix
335 if test x$plugins_loading = xyes; then
336 echo Building dynamic plugins:
337     if test x"$plugin_netstatus" != x; then
338         AC_MSG_RESULT([    netstatus - Monitor networking status])
339     fi
340     if test x"$plugin_netstat" != x; then
341         AC_MSG_RESULT([    netstat - Monitor networking status (Linux Only)])
342     fi
343     if test x"$plugin_volume" != x; then
344         AC_MSG_RESULT([    volume - Display and adjust volume of sound card])
345     fi
346     if test x"$plugin_volumealsa" != x; then
347         AC_MSG_RESULT([    volumealsa - Display and adjust volume of sound card for ALSA])
348     fi
349     if test x"$plugin_cpu" != x; then
350         AC_MSG_RESULT([    cpu - Display CPU loading])
351     fi
352     if test x"$plugin_deskno" != x; then
353         AC_MSG_RESULT([    deskno - Display desktop number])
354     fi
355     if test x"$plugin_batt" != x; then
356         AC_MSG_RESULT([    batt - Monitor battery status])
357     fi
358     if test x"$plugin_kbled" != x; then
359         AC_MSG_RESULT([    kbled - Indicator for CapsLock, NumLock, and ScrLock])
360     fi
361     if test x"$plugin_xkb" != x; then
362         AC_MSG_RESULT([    xkb - Keyboard layout switcher])
363     fi
364     if test x"$plugin_thermal" != x; then
365         AC_MSG_RESULT([    thermal - Temperature monitor])
366     fi
367 else
368 echo Dynamic loader for plugins....... : disabled.
369 fi
370
371 echo
372 echo 'LXPanel requires menu-cache and lxmenu-data packages since'
373 echo 'version 0.4.0. Please make sure they are correctly installed.'
374 echo 'Otherwise, you will not be able to use applications menu.'
375 echo
376