68860fc726b96d0109e3da491da3428edfb2da5a
[debian/lxpanel.git] / configure.ac
1 AC_PREREQ(2.53)
2 AC_INIT(lxpanel, 0.7.2, http://lxde.org/)
3 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects no-dist-gzip dist-xz])
4 AC_CONFIG_HEADER([config.h])
5 AC_CONFIG_MACRO_DIR([m4])
6
7 # Support silent build rules. Disable by either passing --disable-silent-rules
8 # to configure or passing V=1 to make
9 AM_SILENT_RULES([yes])
10
11 # Force to dynamic
12 AC_DISABLE_STATIC
13
14 # Checks for programs.
15 AC_PROG_CC
16 AC_PROG_INSTALL
17 AC_PROG_LN_S
18 IT_PROG_INTLTOOL([0.40.0], [no-xml])
19 AM_PROG_CC_C_O
20 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
21
22 #Initialize libtool
23 LT_PREREQ([2.2])
24 LT_INIT
25
26 # Checks for libraries.
27 AC_ARG_ENABLE(gtk3,
28 AC_HELP_STRING([--enable-gtk3],[enable to use gtk-3.0 instead of gtk-2.0]),
29 [case "${enableval}" in
30   yes)  enable_gtk3=yes ;;
31   no)   enable_gtk3=no ;;
32   *) AC_MSG_ERROR([bad value "${enableval}" for --enable-gtk3, use "yes" (default) or "no".]) ;;
33 esac],[])
34
35 if test "x$enable_gtk3" = "xyes" ; then
36   CFLAGS="$CFLAGS -DENABLE_GTK3"
37   pkg_modules="$pkg_modules gtk+-3.0 libfm-gtk3 >= 1.2.0 libwnck-3.0"
38 else
39   pkg_modules="$pkg_modules gtk+-2.0 >= 2.18.0 libfm-gtk >= 1.2.0 libwnck-1.0"
40 fi
41
42 pkg_modules="$pkg_modules \
43              gio-unix-2.0 \
44              gthread-2.0 \
45              gmodule-2.0"
46 PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
47 AC_SUBST(PACKAGE_CFLAGS)
48 AC_SUBST(PACKAGE_LIBS)
49
50 ###########################
51 # Indicator Info
52 ###########################
53 AC_ARG_ENABLE([indicator_support],
54     AS_HELP_STRING([--enable-indicator-support],
55                [enable plugin loading (default: disable)]),
56                indicator_support=$enableval, indicator_support="no")
57 AM_CONDITIONAL(ENABLE_INDICATOR_SUPPORT, test x"$indicator_support" = x"yes")
58
59 if test "$indicator_support" != "no"; then
60         INDICATOR_REQUIRED_VERSION=0.3.0
61         INDICATOR_PKG_NAME=indicator-0.4
62
63         PKG_CHECK_MODULES(APPLET, $INDICATOR_PKG_NAME >= $INDICATOR_REQUIRED_VERSION)
64         AC_SUBST(APPLET_CFLAGS)
65
66         if test "x$with_localinstall" = "xyes"; then
67                 INDICATORDIR="${libdir}/indicators/2/"
68                 INDICATORICONSDIR="${datadir}/indicator-applet/icons/"
69         else
70                 INDICATORDIR=`$PKG_CONFIG --variable=indicatordir $INDICATOR_PKG_NAME`
71                 INDICATORICONSDIR=`$PKG_CONFIG --variable=iconsdir $INDICATOR_PKG_NAME`
72 fi
73         AC_SUBST(INDICATORDIR)
74         AC_SUBST(INDICATORICONSDIR)
75 fi
76
77
78 pkg_modules="x11"
79 PKG_CHECK_MODULES(X11, [$pkg_modules])
80 AC_SUBST(X11_LIBS)
81
82 pkg_modules="libmenu-cache"
83 PKG_CHECK_MODULES(MENU_CACHE, [$pkg_modules],
84                   enable_menu_cache=yes, enable_menu_cache=no)
85 if test x"$enable_menu_cache" = "xno"; then
86         AC_WARN([No libmenu-cache found.  All menu related routines are not built.])
87         AC_DEFINE(DISABLE_MENU, [1], [Disable menu related routines])
88 fi
89 AC_SUBST(MENU_CACHE_CFLAGS)
90 AC_SUBST(MENU_CACHE_LIBS)
91 AM_CONDITIONAL(ENABLE_MENU_CACHE, test x"$enable_menu_cache" = x"yes")
92
93 AC_ARG_ENABLE(more_warnings,
94        [AC_HELP_STRING([--enable-more-warnings],
95                [Add more warnings @<:@default=no@:>@])],
96        [enable_more_warnings="${enableval}"],
97        [enable_more_warnings=no]
98 )
99
100 if test x"$enable_more_warnings" = x"yes"; then
101   ADDITIONAL_FLAGS="-Wall -Werror=all -Werror=format -Werror=implicit-function-declaration -Werror=implicit-int -Werror=missing-braces -Werror=parentheses -Werror=return-type -Werror=strict-aliasing -Werror=switch -Wuninitialized -Werror=unused-label -Werror=unused-value -Wextra -Wno-missing-field-initializers -Wno-unused-parameter -Werror=missing-declarations -Wredundant-decls -Wmissing-noreturn -Wpointer-arith -Wcast-align -Wwrite-strings -Werror=inline -Werror=format-nonliteral -Wformat-nonliteral -Werror=format-security -Wformat-security -Winit-self -Werror=missing-include-dirs -Werror=undef -Werror=aggregate-return -Wmissing-format-attribute -Werror=nested-externs -fno-strict-aliasing -fmessage-length=0 -Wp,-D_FORTIFY_SOURCE=2 -DG_DISABLE_DEPRECATED -DG_DISABLE_SINGLE_INCLUDES -DGDK_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_DEPRECATED -DGTK_DISABLE_SINGLE_INCLUDES"
102 fi
103 AC_SUBST(ADDITIONAL_FLAGS)
104
105 PACKAGE_CFLAGS="$PACKAGE_CFLAGS $MENU_CACHE_CFLAGS $ADDITIONAL_FLAGS"
106 PACKAGE_LIBS="$PACKAGE_LIBS $MENU_CACHE_LIBS"
107
108 dnl linker tweaking
109 # The function of the link flag --as-needed is to prevent unnecesary linking.
110 # Example: A -> B -> C
111 # Normally, A would link to B and also depend on C, this is of cource
112 # unnecesary. In this situation, however we do need to link to C, so this
113 # must be done explicitly. This flag comes in handy when a library ABI
114 # is changed, minimizing the amount of recompilations needed.
115 AC_MSG_CHECKING([whether $LD accepts --as-needed])
116 case `$LD --as-needed -v 2>&1 </dev/null` in
117 *GNU* | *'with BFD'*)
118     LDFLAGS="$LDFLAGS -Wl,--as-needed"
119     AC_MSG_RESULT([yes])
120     ;;
121 *)
122     AC_MSG_RESULT([no])
123     ;;
124 esac
125
126 dnl linker optimizations
127 AC_MSG_CHECKING([whether $LD accepts -O1])
128 case `$LD -O1 -v 2>&1 </dev/null` in
129 *GNU* | *'with BFD'*)
130   LDFLAGS="$LDFLAGS -Wl,-O1"
131   AC_MSG_RESULT([yes])
132   ;;
133 *)
134   AC_MSG_RESULT([no])
135   ;;
136 esac
137 AC_MSG_CHECKING([whether $LD accepts -Bsymbolic-functions])
138 case `$LD -Bsymbolic-functions -v 2>&1 </dev/null` in
139 *GNU* | *'with BFD'*)
140   LDFLAGS="$LDFLAGS -Wl,-Bsymbolic-functions"
141   AC_MSG_RESULT([yes])
142   ;;
143 *)
144   AC_MSG_RESULT([no])
145   ;;
146 esac
147 AC_MSG_CHECKING([whether $LD accepts --sort-common])
148 case `$LD --sort-common -v 2>&1 </dev/null` in
149 *GNU* | *'with BFD'*)
150   LDFLAGS="$LDFLAGS -Wl,--sort-common"
151   AC_MSG_RESULT([yes])
152   ;;
153 *)
154   AC_MSG_RESULT([no])
155   ;;
156 esac
157
158 dnl FIXME: filter for undefined symbols in plugins
159 # when passing "-z defs" to linker, we would better to make sure
160 # there are no undefined references.  However, we intend not to
161 # fix at the moment since we don't have spin-off libraray containing
162 # the necessary functions.
163 if test ! -z "$LDFLAGS"; then
164     LDFLAGS=`echo "$LDFLAGS" | sed -e 's/-Wl,-z,defs//'`
165 fi
166
167 LXPANEL_MODULE="-avoid-version \
168 -rpath \$(libdir)/lxpanel/plugins \
169 -no-undefined "'-export-symbols-regex "^[[^_]].*"'
170 AC_SUBST(LXPANEL_MODULE)
171
172 AC_ARG_ENABLE([alsa],
173     AS_HELP_STRING([--disable-alsa],
174                     [compile ALSA providers (default: enable)]),
175             compile_alsa=$enableval, compile_alsa="yes")
176 if test x"$compile_alsa" = "xyes"; then
177     AC_CHECK_HEADERS([alsa/asoundlib.h],
178                      [AC_CHECK_LIB([asound],
179                                    [snd_seq_open],
180                                    compile_alsa=yes,compile_alsa=no)],
181                           compile_alsa=no)
182 fi
183 AM_CONDITIONAL(BUILD_ALSA_PLUGINS, test x$compile_alsa = xyes)
184 dnl FIXME: check OSS existence
185 AM_CONDITIONAL(BUILD_OSS_PLUGINS, test x$compile_alsa = xno)
186
187 AC_ARG_ENABLE([plugins-loading],
188     AS_HELP_STRING([--disable-plugins-loading],
189                [disable plugin loading (default: enable)]),
190                plugins_loading=$enableval, plugins_loading="yes")
191
192 AM_CONDITIONAL(BUILD_PLUGIN_LOADER, test x$plugins_loading = xyes)
193
194 if test x"$plugins_loading" = "xno"; then
195     AC_DEFINE(DISABLE_PLUGINS_LOADING, [1], [Disable plugin loading])
196 fi
197
198 dnl Here are plugin listing.
199 plugin_netstatus=
200 plugin_netstat=
201 plugin_volume=
202 plugin_volumealsa=
203 plugin_cpu=
204 plugin_deskno=
205 plugin_batt=
206 plugin_xkb=
207 plugin_kbled=
208 plugin_thermal=
209 plugin_cpufreq=
210 plugin_monitors=
211 plugin_indicator=
212
213 AC_MSG_CHECKING([which plugins should be built dynamically])
214 AC_ARG_WITH(plugins,
215 [  --with-plugins=<list>  compile dynamic plugins in <list> ]
216 [                         plugins may be comma separated ]
217 [                         'all' builds all plugins (default), 'none' builds none ]
218 [                         plugins prefixed with '-' are not built]
219 [                         Possible plugins are: ]
220 [                         netstatus, netstat, volume, volumealsa, cpu, deskno, batt,]
221 [                         kbled, xkb, thermal, cpufreq, monitors, indicator, weather]
222 , plugins="$withval",[plugins="all"])
223
224 if test x"$plugins" != xall -a x"$plugins" != xnone; then
225     if test x"$plugins_loading" = xno; then
226         AC_MSG_ERROR(
227         [--disable-plugins-loading and --with-plugins conflict each other.])
228     fi
229 fi
230
231 ALL_PLUGINS_LIST="netstatus netstat volume volumealsa cpu deskno batt kbled xkb thermal cpufreq monitors indicator weather"
232 AC_SUBST(ALL_PLUGINS_LIST)
233
234 AC_DEFUN([check_plugin_name],[
235     plugin_found=false
236     for name in $ALL_PLUGINS_LIST; do
237         if test x[$1] = x[$name]; then
238             plugin_found=true
239         fi
240     done
241     if test x[$plugin_found] = false; then
242         echo [Unknown plugin $1.]
243         exit 1
244     fi
245 ])
246
247 if test "$plugins" != "none"; then
248     plugins=`echo $plugins | sed 's/,/ /g'`
249     for plugin in $plugins
250     do
251         case "$plugin" in
252             all)
253                 for name in $ALL_PLUGINS_LIST
254                 do
255                     export plugin_$name="$name.la"
256                 done
257                 ;;
258             -*)
259                 check_plugin_name([${plugin#-}])
260                 export plugin_${plugin#-}=
261                 ;;
262             *)
263                 check_plugin_name([$plugin])
264                 export plugin_$plugin=$plugin.la
265                 ;;
266         esac
267     done
268     AC_MSG_RESULT($plugins)
269 fi
270
271 dnl FIXME: OSS/ALSA checking
272 if test x"$compile_alsa" = "xno"; then
273     if test ! -z $plugin_volumealsa; then
274         AC_MSG_RESULT([no ALSA headers/libraries found!])
275         plugin_volumealsa=
276     fi
277 else
278     dnl force OSS plugin to <null>
279     plugin_volume=
280 fi
281
282 dnl Exclude indicator support when there is no support.
283 if test x"$indicator_support" = "xno"; then
284     plugin_indicator=
285 fi
286
287 PLUGINS_LIST="\
288     $plugin_netstatus \
289     $plugin_netstat \
290     $plugin_volume \
291     $plugin_volumealsa \
292     $plugin_cpu \
293     $plugin_deskno \
294     $plugin_batt \
295     $plugin_kbled \
296     $plugin_xkb \
297     $plugin_thermal \
298     $plugin_cpufreq \
299     $plugin_monitors \
300     $plugin_indicator \
301     $plugin_weather"
302
303 AC_SUBST(PLUGINS_LIST)
304
305 # Plugin-specific dependencies
306 # nestat
307 if test x"$plugin_netstat" != "x";then
308 AC_CHECK_HEADER([iwlib.h],,
309  AC_MSG_ERROR([netstat plugin requires wireless-tools-devel]))
310 fi
311
312 # weather
313 if test x"$plugin_weather" != "x";then
314 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
315 AC_SUBST(LIBXML2_CFLAGS)
316 AC_SUBST(LIBXML2_LIBS)
317 fi
318
319 # Checks for header files.
320 AC_PATH_X
321 AC_HEADER_STDC
322 AC_HEADER_SYS_WAIT
323 AC_CHECK_HEADERS([locale.h stdlib.h string.h sys/time.h unistd.h])
324
325 # Checks for typedefs, structures, and compiler characteristics.
326 AC_C_CONST
327 AC_C_INLINE
328 AC_STRUCT_TM
329
330 # Checks for library functions.
331 AC_FUNC_MALLOC
332 AC_FUNC_MEMCMP
333 AC_TYPE_SIGNAL
334 AC_FUNC_STAT
335 AC_FUNC_STRFTIME
336 AC_CHECK_FUNCS([bzero memset mkdir setlocale strchr])
337
338 dnl check for menu-cache versions 0.4.x since no macro MENU_CACHE_CHECK_VERSION
339 dnl is available in those versions
340 LIBS_save="${LIBS}"
341 LIBS="${LIBS} ${MENU_CACHE_LIBS}"
342 AC_CHECK_FUNCS(menu_cache_dir_list_children)
343 LIBS="${LIBS_save}"
344
345 # Generate po/LINGUAS on the fly rather than relying on translators
346 # to maintain it manually. This also overcome the problem that Transifex
347 # cannot add a language to po/LINGUAS if a new po file is submitted.
348 rm -f $srcdir/po/LINGUAS
349 for po_file in `ls $srcdir/po/*.po | sort`;
350 do
351     lang=`echo "$po_file" | sed "s|.*/po/\(.*\)\.po|\1|g"`
352     echo $lang >> $srcdir/po/LINGUAS
353 done
354
355 GETTEXT_PACKAGE=lxpanel
356 AC_SUBST(GETTEXT_PACKAGE)
357 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
358
359 AM_GLIB_GNU_GETTEXT
360
361 AC_ARG_ENABLE(debug,
362     [AC_HELP_STRING([--enable-debug],
363         [enable debug support @<:@default=no@:>@])],
364     [enable_debug="${enableval}"],
365     [enable_debug=no]
366 )
367 if test "$enable_debug" = "yes"; then
368     # turn on debug and disable optimization
369     CPPFLAGS="$CPPFLAGS -DG_ENABLE_DEBUG -O0 -g"
370     case "$CC" in
371     gcc*)
372         CPPFLAGS="$CPPFLAGS -Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers -Werror=implicit-function-declaration"
373         ;;
374     *)
375         ;;
376     esac
377     dnl Be more strict on portability
378     #CPPFLAGS="$CPPFLAGS -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=700"
379 else
380     # turn off glib debug checks
381     CPPFLAGS="$CPPFLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
382 fi
383
384 dnl Fix invalid sysconfdir when --prefix=/usr
385 if test `eval "echo $sysconfdir"` = /usr/etc
386 then
387     sysconfdir=/etc
388 fi
389
390 AC_CONFIG_FILES([
391     lxpanel.pc
392     Makefile
393     src/Makefile
394     plugins/Makefile
395     po/Makefile.in
396     data/Makefile
397     data/default/panels/panel
398     data/two_panels/panels/top
399     data/two_panels/panels/bottom
400     man/Makefile
401 ])
402 AC_OUTPUT
403
404 echo
405 echo lxpanel ......................... : Version $VERSION
406 echo
407 echo Prefix........................... : $prefix
408 echo System config directory.......... : `eval "echo $sysconfdir"`
409 echo
410
411 if test x$plugins_loading = xyes; then
412 echo Building dynamic plugins:
413     if test x"$plugin_netstatus" != x; then
414         AC_MSG_RESULT([    netstatus - Monitor networking status])
415     fi
416     if test x"$plugin_netstat" != x; then
417         AC_MSG_RESULT([    netstat - Monitor networking status])
418     fi
419     if test x"$plugin_volume" != x; then
420         AC_MSG_RESULT([    volume - Display and adjust volume of sound card for OSS])
421     fi
422     if test x"$plugin_volumealsa" != x; then
423         AC_MSG_RESULT([    volumealsa - Display and adjust volume of sound card for ALSA])
424     fi
425     if test x"$plugin_cpu" != x; then
426         AC_MSG_RESULT([    cpu - Display CPU loading])
427     fi
428     if test x"$plugin_deskno" != x; then
429         AC_MSG_RESULT([    deskno - Display desktop number])
430     fi
431     if test x"$plugin_batt" != x; then
432         AC_MSG_RESULT([    batt - Monitor battery status])
433     fi
434     if test x"$plugin_kbled" != x; then
435         AC_MSG_RESULT([    kbled - Indicator for CapsLock, NumLock, and ScrLock])
436     fi
437     if test x"$plugin_xkb" != x; then
438         AC_MSG_RESULT([    xkb - Keyboard layout handler])
439     fi
440     if test x"$plugin_thermal" != x; then
441         AC_MSG_RESULT([    thermal - Temperature monitor])
442     fi
443     if test x"$plugin_cpufreq" != x; then
444         AC_MSG_RESULT([    cpufreq - CpuFreq frontend])
445     fi
446     if test x"$plugin_monitors" != x; then
447         AC_MSG_RESULT([    monitors - Monitors for CPU & RAM])
448     fi
449     if test x"$plugin_indicator" != x; then
450         AC_MSG_RESULT([    indicator - Indicator support])
451     fi
452     if test x"$plugin_weather" != x; then
453         AC_MSG_RESULT([    weather - Weather conditions and forecast])
454     fi
455 else
456 echo Dynamic loader for plugins....... : disabled.
457 fi
458
459 if test x"$sysconfdir" != x'/etc'; then
460     echo
461     echo 'Warning: sysconfdir is not /etc. It might be not what you want.'
462     echo 'Please consider passing --sysconfdir=/etc to configure.'
463 fi
464
465 echo
466 echo 'LXPanel requires menu-cache and lxmenu-data packages since'
467 echo 'version 0.4.0. Please make sure they are correctly installed.'
468 echo 'Otherwise, you will not be able to use applications menu.'
469 echo
470