Removing override_dh_auto_test target since upstream fixed the problem.
[debian/lxappearance.git] / configure.ac
1 #                                               -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3 AC_PREREQ([2.64])
4 AC_INIT([lxappearance],[0.5.6],[http://lxde.org/])
5 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign subdir-objects no-dist-gzip dist-xz])
6
7 # intltool
8 IT_PROG_INTLTOOL([0.40.0])
9
10 # Support silent build rules. Disable by either passing --disable-silent-rules
11 # to configure or passing V=1 to make
12 AM_SILENT_RULES([yes])
13
14 AC_CONFIG_HEADERS([config.h])
15 AC_CONFIG_MACRO_DIR([.])
16
17 # C compiler
18 AC_PROG_CC
19 AC_PROG_INSTALL
20 AM_PROG_CC_C_O
21 AC_PROG_CC_STDC
22
23 # Checks for libraries.
24
25 # Checks for header files.
26
27 # Checks for typedefs, structures, and compiler characteristics.
28
29 # Checks for library functions.
30
31
32 AC_ARG_ENABLE(man,
33 AS_HELP_STRING([--enable-man],[regenerate roff man pages from Docbook @<:@default=yes@:>@]),
34 [case "${enableval}" in
35   yes)  enable_man=yes ;;
36   no)   enable_man=no ;;
37   *) AC_MSG_ERROR([bad value "${enableval}" for --enable-man, use "yes" (default) or "no".]) ;;
38 esac],[])
39
40 AC_ARG_ENABLE(more_warnings,
41        [AS_HELP_STRING([--enable-more-warnings],
42                [Add more warnings @<:@default=no@:>@])],
43        [enable_more_warnings="${enableval}"],
44        [enable_more_warnings=no]
45 )
46
47 AC_ARG_ENABLE(gtk3,
48 AS_HELP_STRING([--enable-gtk3],[enable to use gtk-3.0 instead of gtk-2.0]),
49 [case "${enableval}" in
50   yes)  enable_gtk3=yes ;;
51   no)   enable_gtk3=no ;;
52   *) AC_MSG_ERROR([bad value "${enableval}" for --enable-gtk3, use "yes" (default) or "no".]) ;;
53 esac],[])
54
55 PKG_CHECK_MODULES(XLIB, "x11")
56 AC_SUBST(XLIB_CFLAGS)
57 AC_SUBST(XLIB_LIBS)
58
59 if test "x$enable_gtk3" = "xyes" ; then
60   CFLAGS="$CFLAGS -DENABLE_GTK3"
61   gtk_modules="gtk+-3.0 >= 3.0.0 gthread-2.0"
62 else
63   gtk_modules="gtk+-2.0 >= 2.12.0 gthread-2.0"
64 fi
65
66 PKG_CHECK_MODULES(GTK, [$gtk_modules])
67 AC_SUBST(GTK_CFLAGS)
68 AC_SUBST(GTK_LIBS)
69
70 AC_ARG_ENABLE(dbus,
71        [AS_HELP_STRING([--enable-dbus],
72                [Use Dbus support (usefull for lxsession > 0.4.9) @<:@default=no@:>@])],
73        [enable_dbus="${enableval}"],
74        [enable_dbus=no]
75 )
76
77
78 if test x"$enable_dbus" = x"yes"; then
79        PKG_CHECK_MODULES(DBUS, [dbus-1 >= 0.95 dbus-glib-1 >= 0.70])
80        CFLAGS="$CFLAGS -DENABLE_DBUS"
81 fi
82 AC_SUBST(DBUS_CFLAGS)
83 AC_SUBST(DBUS_LIBS)
84
85
86
87 gmodule_modules="gmodule-export-2.0"
88 PKG_CHECK_MODULES(GMODULE, [$gmodule_modules])
89 AC_SUBST(GMODULE_CFLAGS)
90 AC_SUBST(GMODULE_LIBS)
91
92 # gio_modules="gthread-2.0 gio-unix-2.0 glib-2.0 >= 2.18.0"
93 # PKG_CHECK_MODULES(GIO, [$gio_modules])
94 # AC_SUBST(GIO_CFLAGS)
95 # AC_SUBST(GIO_LIBS)
96
97 # menu_modules="libmenu-cache >= 0.3.2"
98 # PKG_CHECK_MODULES(MENU_CACHE, [$menu_modules])
99 # AC_SUBST(MENU_CACHE_CFLAGS)
100 # AC_SUBST(MENU_CACHE_LIBS)
101
102 if test x"$enable_more_warnings" = x"yes"; then
103   ADDITIONAL_FLAGS="-Wall -Werror=all -Werror=format -Werror=implicit-function-declaration -Werror=implicit-int -Werror=missing-braces -Werror=parentheses -Werror=return-type -Werror=strict-aliasing -Werror=switch -Wuninitialized -Werror=unused-label -Werror=unused-value -Wextra -Wno-missing-field-initializers -Wno-unused-parameter -Werror=missing-declarations -Wredundant-decls -Wmissing-noreturn -Wpointer-arith -Wcast-align -Wwrite-strings -Werror=inline -Werror=format-nonliteral -Wformat-nonliteral -Werror=format-security -Wformat-security -Winit-self -Werror=missing-include-dirs -Werror=undef -Werror=aggregate-return -Wmissing-format-attribute -Werror=nested-externs -fno-strict-aliasing -fmessage-length=0 -Wp,-D_FORTIFY_SOURCE=2 -DG_DISABLE_DEPRECATED -DG_DISABLE_SINGLE_INCLUDES -DGDK_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_DEPRECATED -DGTK_DISABLE_SINGLE_INCLUDES"
104 fi
105 AC_SUBST(ADDITIONAL_FLAGS)
106
107 AC_ARG_ENABLE(debug,
108     [AC_HELP_STRING([--enable-debug],
109         [build lxappearance with debug support @<:@default=no@:>@])],
110     [enable_debug="${enableval}"],
111     [enable_debug=no]
112 )
113
114 if test "$enable_debug" = "yes"; then
115     # turn on debug and disable optimization
116     CPPFLAGS="$CPPFLAGS -DG_ENABLE_DEBUG -O0 -g"
117     case "$CC" in
118     gcc*)
119         CPPFLAGS="$CPPFLAGS -Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers"
120         ;;
121     *)
122         ;;
123     esac
124     dnl Be more strict on portability
125     CPPFLAGS="$CPPFLAGS -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=700"
126 else
127     # turn off glib debug checks
128     CPPFLAGS="$CPPFLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
129 fi
130
131 # Generate po/LINGUAS on the fly rather than relying on translators
132 # to maintain it manually. This also overcome the problem that Transifex
133 # cannot add a language to po/LINGUAS if a new po file is submitted.
134 rm -f $srcdir/po/LINGUAS
135 for po_file in `ls $srcdir/po/*.po | sort`;
136 do
137     lang=`echo "$po_file" | sed "s|.*/po/\(.*\)\.po|\1|g"`
138     echo $lang >> $srcdir/po/LINGUAS
139 done
140
141 GETTEXT_PACKAGE=lxappearance
142 AC_SUBST(GETTEXT_PACKAGE)
143 AM_GLIB_GNU_GETTEXT
144 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
145
146 if test x"$enable_man" = x"yes"; then
147         AC_PATH_PROG([XSLTPROC], [xsltproc])
148         if test -z "$XSLTPROC"; then
149                 enable_man=no
150         fi
151
152         dnl check for DocBook DTD and stylesheets in the local catalog.
153         JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
154                 [DocBook XML DTD V4.1.2], [], enable_man=no)
155         JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
156                 [DocBook XSL Stylesheets >= 1.70.1], [], enable_man=no)
157 fi
158
159 AM_CONDITIONAL(ENABLE_MAN, test "x$enable_man" != "xno")
160
161 AC_CONFIG_FILES([
162     Makefile
163     data/Makefile
164     data/ui/Makefile
165     data/ui/about.glade
166     data/lxappearance.pc
167     man/Makefile
168     po/Makefile.in
169     src/Makefile
170 ])
171
172 AC_OUTPUT
173
174 echo
175 echo lxappearance....................... : Version $VERSION
176 echo
177 echo Enable debug....................: "$enable_debug"
178 echo Enable Dbus support.............: "$enable_dbus"
179 echo Prefix..........................: $prefix
180 echo
181 echo The binary will be installed in $prefix/bin
182 echo
183 echo http://lxde.org/
184 echo
185 echo "Ready to make lxappearance. Type 'make' to continue."
186 echo
187